configure.ac

   1 AC_PREREQ(2.50)
   2 AC_INIT([onak],[0.4.1],[noodles-onak@earth.li])
   3 AC_CONFIG_SRCDIR(onak.c)
   4 AC_CONFIG_HEADER(config.h)
   5
   6 AC_PROG_CC
   7 AC_PROG_CC_C99
   8
   9 AC_C_BIGENDIAN
  10
  11 m4_include([m4/ax_lib_nettle.m4])
  12
  13 AX_LIB_NETTLE(auto)
  14
  15 dnl We should always have these backends available.
  16 backends="file fs keyd"
  17
  18 LIBCURL_CHECK_CONFIG(,,[have_libcurl="yes" backends="$backends hkp"],have_libcurl="no")
  19
  20 AC_CHECK_LIB(pq, PQsetdbLogin,[have_libpq="yes" backends="$backends pg"],have_libpq="no")
  21
  22 AC_CHECK_HEADER(db.h, have_db_h="yes", have_db_h="no")
  23 AC_MSG_CHECKING(for libdb version in db.h)
  24 printf "#include <db.h>\nDB_VERSION_MAJOR DB_VERSION_MINOR\n" >conftest.c
  25 set `eval $ac_cpp conftest.c | egrep '^ *[[0-9]] *'`; v="$1"; vv="$2"
  26 AC_MSG_RESULT($v.$vv)
  27 if test "$v" -ge 4; then
  28         for db in "db-$v.$vv" "db$v.$vv" "db-$v" "db$v" "db"; do
  29                 AC_MSG_CHECKING(for db_create in lib$db)
  30                 oldLIBS="$LIBS"
  31                 LIBS="$LIBS -l$db"
  32                 db4libs="-l$db"
  33                 AC_TRY_LINK([#include <db.h>], db_create(0, 0, 0),
  34                         have_libdb="yes", have_libdb="no")
  35                 AC_MSG_RESULT($have_libdb)
  36                 LIBS="$oldLIBS"
  37                 if test "$have_libdb" != "no"; then break; fi
  38         done
  39 fi
  40 if test "$have_libdb" = "yes" -a "$have_db_h" = "yes"; then
  41         AC_DEFINE(HAVE_LIBDB4, 1, [libdb found])
  42         backends="$backends db4"
  43 fi
  44
  45 AC_MSG_CHECKING(available backends)
  46 AC_MSG_RESULT($backends)
  47
  48 AC_ARG_ENABLE(backend,AC_HELP_STRING([--enable-backend=<backend>],[Choose the backend database to use. Defaults to dynamic.]), [], [enable_backend="dynamic"])
  49
  50 AC_ARG_ENABLE(keyd,AC_HELP_STRING([--enable-keyd],[Use keyd as the DB backend.]), [], [])
  51
  52 AC_MSG_CHECKING([which key database backend to use])
  53 AC_MSG_RESULT([$enable_backend])
  54 AC_CHECK_FILE([$srcdir/keydb_$enable_backend.c], ,AC_MSG_ERROR([non existent key database backend $enable_backend]))
  55
  56 if test "x$enable_backend" = "xdb4"
  57 then
  58         if test "$have_libdb" = "no" -o "$have_db_h" = "no"; then
  59                 AC_MSG_ERROR(libdb not found.)
  60         fi
  61         LIBS="$LIBS $db4libs"
  62 else if test "x$enable_backend" = "xpg"
  63 then
  64         if test "$have_libpq" = "no"; then
  65                 AC_MSG_ERROR(libpq not found.)
  66         fi
  67         LIBS="$LIBS -lpq"
  68 fi
  69 fi
  70
  71 dnl If we are explicitly told which backend to use, only build that one.
  72 if test "x$enable_backend" = "xdb4"
  73 then
  74         backend="$enable_backend"
  75 fi
  76
  77 AC_SUBST(DBTYPE, $enable_backend)
  78 AC_SUBST(DB4LIBS, $db4libs)
  79 AC_SUBST(KEYD, $enable_keyd)
  80 AC_SUBST(BACKENDS, $backends)
  81
  82 AC_CONFIG_FILES(Makefile)
  83
  84 AC_OUTPUT