twirssi.pl

   1 use strict;
   2 use Irssi;
   3 use Irssi::Irc;
   4 use Net::Twitter;
   5 use HTTP::Date;
   6 use HTML::Entities;
   7 use File::Temp;
   8 use LWP::Simple;
   9 use Data::Dumper;
  10 $Data::Dumper::Indent = 1;
  11
  12 use vars qw($VERSION %IRSSI);
  13
  14 $VERSION = "1.5.2";
  15 my ($REV) = '$Rev: 326 $' =~ /(\d+)/;
  16 %IRSSI = (
  17     authors     => 'Dan Boger',
  18     contact     => 'zigdon@gmail.com',
  19     name        => 'twirssi',
  20     description => 'Send twitter updates using /tweet.  '
  21       . 'Can optionally set your bitlbee /away message to same',
  22     license => 'GNU GPL v2',
  23     url     => 'http://tinyurl.com/twirssi',
  24     changed => 'Mon Dec  1 15:36:01 PST 2008',
  25 );
  26
  27 my $window;
  28 my $twit;
  29 my %twits;
  30 my $user;
  31 my $poll;
  32 my %nicks;
  33 my %friends;
  34 my $last_poll = time - 300;
  35 my %tweet_cache;
  36
  37 sub cmd_direct {
  38     my ( $data, $server, $win ) = @_;
  39
  40     unless ($twit) {
  41         &notice("Not logged in!  Use /twitter_login username pass!");
  42         return;
  43     }
  44
  45     my ( $target, $text ) = split ' ', $data, 2;
  46     unless ( $target and $text ) {
  47         &notice("Usage: /dm <nick> <message>");
  48         return;
  49     }
  50
  51     &cmd_direct_as( "$user $data", $server, $win );
  52 }
  53
  54 sub cmd_direct_as {
  55     my ( $data, $server, $win ) = @_;
  56
  57     unless ($twit) {
  58         &notice("Not logged in!  Use /twitter_login username pass!");
  59         return;
  60     }
  61
  62     my ( $username, $target, $text ) = split ' ', $data, 3;
  63     unless ( $username and $target and $text ) {
  64         &notice("Usage: /dm_as <username> <nick> <message>");
  65         return;
  66     }
  67
  68     unless ( exists $twits{$username} ) {
  69         &notice("Unknown username $username");
  70         return;
  71     }
  72
  73     unless ( $twits{$username}
  74         ->new_direct_message( { user => $target, text => $text } ) )
  75     {
  76         &notice("DM to $target failed");
  77         return;
  78     }
  79
  80     &notice("DM sent to $target");
  81     $nicks{$target} = time;
  82 }
  83
  84 sub cmd_tweet {
  85     my ( $data, $server, $win ) = @_;
  86
  87     unless ($twit) {
  88         &notice("Not logged in!  Use /twitter_login username pass!");
  89         return;
  90     }
  91
  92     $data =~ s/^\s+|\s+$//;
  93     unless ($data) {
  94         &notice("Usage: /tweet <update>");
  95         return;
  96     }
  97
  98     &cmd_tweet_as( "$user $data", $server, $win );
  99 }
 100
 101 sub cmd_tweet_as {
 102     my ( $data, $server, $win ) = @_;
 103
 104     unless ($twit) {
 105         &notice("Not logged in!  Use /twitter_login username pass!");
 106         return;
 107     }
 108
 109     $data =~ s/^\s+|\s+$//;
 110     my ( $username, $data ) = split ' ', $data, 2;
 111
 112     unless ( $username and $data ) {
 113         &notice("Usage: /tweet_as <username> <update>");
 114         return;
 115     }
 116
 117     unless ( exists $twits{$username} ) {
 118         &notice("Unknown username $username");
 119         return;
 120     }
 121
 122     if ( Irssi::settings_get_str("short_url_provider") ) {
 123         foreach my $url ( $data =~ /(https?:\/\/\S+[\w\/])/g ) {
 124             eval {
 125                 my $short = makeashorterlink($url);
 126                 $data =~ s/\Q$url/$short/g;
 127             };
 128         }
 129     }
 130
 131     if ( length $data > 140 ) {
 132         &notice(
 133             "Tweet too long (" . length($data) . " characters) - aborted" );
 134         return;
 135     }
 136
 137     unless ( $twits{$username}->update($data) ) {
 138         &notice("Update failed");
 139         return;
 140     }
 141
 142     foreach ( $data =~ /@([-\w]+)/ ) {
 143         $nicks{$1} = time;
 144     }
 145
 146     my $away = 0;
 147     if (    Irssi::settings_get_bool("tweet_to_away")
 148         and $data !~ /\@\w/
 149         and $data !~ /^[dD] / )
 150     {
 151         my $server =
 152           Irssi::server_find_tag( Irssi::settings_get_str("bitlbee_server") );
 153         if ($server) {
 154             $server->send_raw("away :$data");
 155             $away = 1;
 156         } else {
 157             &notice( "Can't find bitlbee server.",
 158                 "Update bitlbee_server or disalbe tweet_to_away" );
 159         }
 160     }
 161
 162     &notice( "Update sent" . ( $away ? " (and away msg set)" : "" ) );
 163 }
 164
 165 sub gen_cmd {
 166     my ( $usage_str, $api_name, $post_ref ) = @_;
 167
 168     return sub {
 169         my ( $data, $server, $win ) = @_;
 170
 171         unless ($twit) {
 172             &notice("Not logged in!  Use /twitter_login username pass!");
 173             return;
 174         }
 175
 176         $data =~ s/^\s+|\s+$//;
 177         unless ($data) {
 178             &notice("Usage: $usage_str");
 179             return;
 180         }
 181
 182         unless ( $twit->$api_name($data) ) {
 183             &notice("$api_name failed");
 184             return;
 185         }
 186
 187         &$post_ref($data) if $post_ref;
 188       }
 189 }
 190
 191 sub cmd_switch {
 192     my ( $data, $server, $win ) = @_;
 193
 194     $data =~ s/^\s+|\s+$//g;
 195     if ( exists $twits{$data} ) {
 196         &notice("Switching to $data");
 197         $twit = $twits{$data};
 198         $user = $data;
 199     } else {
 200         &notice("Unknown user $data");
 201     }
 202 }
 203
 204 sub cmd_logout {
 205     my ( $data, $server, $win ) = @_;
 206
 207     $data =~ s/^\s+|\s+$//g;
 208     if ( $data and exists $twits{$data} ) {
 209         &notice("Logging out $data...");
 210         $twits{$data}->end_session();
 211         delete $twits{$data};
 212     } elsif ($data) {
 213         &notice("Unknown username '$data'");
 214     } else {
 215         &notice("Logging out $user...");
 216         $twit->end_session();
 217         undef $twit;
 218         delete $twits{$user};
 219         if ( keys %twits ) {
 220             &cmd_switch( ( keys %twits )[0], $server, $win );
 221         } else {
 222             Irssi::timeout_remove($poll) if $poll;
 223             undef $poll;
 224         }
 225     }
 226 }
 227
 228 sub cmd_login {
 229     my ( $data, $server, $win ) = @_;
 230     my $pass;
 231     if ($data) {
 232         ( $user, $pass ) = split ' ', $data, 2;
 233     } elsif ( my $autouser = Irssi::settings_get_str("twitter_usernames")
 234         and my $autopass = Irssi::settings_get_str("twitter_passwords") )
 235     {
 236         my @user = split /\s*,\s*/, $autouser;
 237         my @pass = split /\s*,\s*/, $autopass;
 238         if ( @user != @pass ) {
 239             &notice("Number of usernames doesn't match "
 240                   . "the number of passwords - auto-login failed" );
 241         } else {
 242             my ( $u, $p );
 243             while ( @user and @pass ) {
 244                 $u = shift @user;
 245                 $p = shift @pass;
 246                 &cmd_login("$u $p");
 247             }
 248             return;
 249         }
 250     } else {
 251         &notice("/twitter_login requires either a username and password "
 252               . "or twitter_usernames and twitter_passwords to be set." );
 253         return;
 254     }
 255
 256     %friends = %nicks = ();
 257
 258     $twit = Net::Twitter->new(
 259         username => $user,
 260         password => $pass,
 261         source   => "twirssi"
 262     );
 263
 264     unless ( $twit->verify_credentials() ) {
 265         &notice("Login as $user failed");
 266         $twit = undef;
 267         if ( keys %twits ) {
 268             &cmd_switch( ( keys %twits )[0], $server, $win );
 269         }
 270         return;
 271     }
 272
 273     if ($twit) {
 274         my $rate_limit = $twit->rate_limit_status();
 275         if ( $rate_limit and $rate_limit->{remaining_hits} < 1 ) {
 276             &notice("Rate limit exceeded, try again later");
 277             $twit = undef;
 278             return;
 279         }
 280
 281         $twits{$user} = $twit;
 282         Irssi::timeout_remove($poll) if $poll;
 283         $poll = Irssi::timeout_add( 300 * 1000, \&get_updates, "" );
 284         &notice("Logged in as $user, loading friends list...");
 285         &load_friends;
 286         &notice( "loaded friends: ", scalar keys %friends );
 287         if ( Irssi::settings_get_bool("twirssi_first_run") ) {
 288             Irssi::settings_set_bool( "twirssi_first_run", 0 );
 289             unless ( exists $friends{twirssi} ) {
 290                 &notice("Welcome to twirssi!"
 291                       . "  Perhaps you should add \@twirssi to your friends list,"
 292                       . " so you can be notified when a new version is release?"
 293                       . "  Just type /twitter_friend twirssi." );
 294             }
 295         }
 296         %nicks = %friends;
 297         $nicks{$user} = 0;
 298         &get_updates;
 299     } else {
 300         &notice("Login failed");
 301     }
 302 }
 303
 304 sub cmd_upgrade {
 305     my ( $data, $server, $win ) = @_;
 306
 307     my $loc = Irssi::settings_get_str("twirssi_location");
 308     unless ( -w $loc ) {
 309         &notice(
 310 "$loc isn't writable, can't upgrade.  Perhaps you need to /set twirssi_location?"
 311         );
 312         return;
 313     }
 314
 315     if ( not -x "/usr/bin/md5sum" and not $data ) {
 316         &notice(
 317 "/usr/bin/md5sum can't be found - try '/twirssi_upgrade nomd5' to skip MD5 verification"
 318         );
 319         return;
 320     }
 321
 322     my $md5;
 323     unless ($data) {
 324         eval { use Digest::MD5; };
 325
 326         if ($@) {
 327             &notice(
 328 "Failed to load Digest::MD5.  Try '/twirssi_upgrade nomd5' to skip MD5 verification"
 329             );
 330             return;
 331         }
 332
 333         $md5 = get("http://irc.peeron.com/~zigdon/twirssi/md5sum");
 334         chomp $md5;
 335         $md5 =~ s/ .*//;
 336         unless ($md5) {
 337             &notice("Failed to download md5sum from peeron!  Aborting.");
 338             return;
 339         }
 340
 341         unless ( open( CUR, $loc ) ) {
 342             &notice(
 343 "Failed to read $loc.  Check that /set twirssi_location is set to the correct location."
 344             );
 345             return;
 346         }
 347
 348         my $cur_md5 = Digest::MD5::md5_hex(<CUR>);
 349         close CUR;
 350
 351         if ( $cur_md5 eq $md5 ) {
 352             &notice("Current twirssi seems to be up to date.");
 353             return;
 354         }
 355     }
 356
 357     my $URL = "http://irc.peeron.com/~zigdon/twirssi/twirssi.pl";
 358     &notice("Downloading twirssi from $URL");
 359     LWP::Simple::getstore( $URL, "$loc.upgrade" );
 360
 361     unless ($data) {
 362         unless ( open( NEW, "$loc.upgrade" ) ) {
 363             &notice(
 364 "Failed to read $loc.upgrade.  Check that /set twirssi_location is set to the correct location."
 365             );
 366             return;
 367         }
 368
 369         my $new_md5 = Digest::MD5::md5_hex(<NEW>);
 370         close NEW;
 371
 372         if ( $new_md5 ne $md5 ) {
 373             &notice("MD5 verification failed. expected $md5, got $new_md5");
 374             return;
 375         }
 376     }
 377
 378     rename $loc, "$loc.backup"
 379       or &notice("Failed to back up $loc: $!.  Aborting")
 380       and return;
 381     rename "$loc.upgrade", $loc
 382       or &notice("Failed to rename $loc.upgrade: $!.  Aborting")
 383       and return;
 384
 385     my ( $dir, $file ) = ( $loc =~ m{(.*)/([^/]+)$} );
 386     if ( -e "$dir/autorun/$file" ) {
 387         &notice("Updating $dir/autorun/$file");
 388         unlink "$dir/autorun/$file"
 389           or &notice("Failed to remove old $file from autorun: $!");
 390         symlink "../$file", "$dir/autorun/$file"
 391           or &notice("Failed to create symlink in autorun directory: $!");
 392     }
 393
 394     &notice("Download complete.  Reload twirssi with /script load $file");
 395 }
 396
 397 sub load_friends {
 398     my $page = 1;
 399     my %new_friends;
 400     while (1) {
 401         my $friends = $twit->friends( { page => $page } );
 402         last unless $friends;
 403         $new_friends{ $_->{screen_name} } = time foreach @$friends;
 404         $page++;
 405         last if @$friends == 0 or $page == 10;
 406         $friends = $twit->friends( page => $page );
 407     }
 408
 409     foreach ( keys %new_friends ) {
 410         next if exists $friends{$_};
 411         $friends{$_} = time;
 412     }
 413
 414     foreach ( keys %friends ) {
 415         delete $friends{$_} unless exists $new_friends{$_};
 416     }
 417 }
 418
 419 sub get_updates {
 420     print scalar localtime, " - get_updates starting" if &debug;
 421
 422     $window =
 423       Irssi::window_find_name( Irssi::settings_get_str('twitter_window') );
 424     unless ($window) {
 425         Irssi::active_win()
 426           ->print( "Can't find a window named '"
 427               . Irssi::settings_get_str('twitter_window')
 428               . "'.  Create it or change the value of twitter_window" );
 429     }
 430     unless ($twit) {
 431         &notice("Not logged in!  Use /twitter_login username pass!");
 432         return;
 433     }
 434
 435     my ( $fh, $filename ) = File::Temp::tempfile();
 436     my $pid = fork();
 437
 438     if ($pid) {    # parent
 439         Irssi::timeout_add_once( 5000, 'monitor_child', [$filename] );
 440         Irssi::pidwait_add($pid);
 441     } elsif ( defined $pid ) {    # child
 442         close STDIN;
 443         close STDOUT;
 444         close STDERR;
 445
 446         my $new_poll = time;
 447
 448         &do_updates( $fh, $user, $twit );
 449         foreach ( keys %twits ) {
 450             next if $_ eq $user;
 451             &do_updates( $fh, $_, $twits{$_} );
 452         }
 453
 454         print $fh "__friends__\n";
 455         &load_friends;
 456         foreach ( sort keys %friends ) {
 457             print $fh "$_ $friends{$_}\n";
 458         }
 459         print $fh $new_poll;
 460         close $fh;
 461         exit;
 462     }
 463     print scalar localtime, " - get_updates ends" if &debug;
 464 }
 465
 466 sub do_updates {
 467     my ( $fh, $username, $obj ) = @_;
 468
 469     print scalar localtime, " - Polling for updates for $username" if &debug;
 470     my $tweets =
 471       $obj->friends_timeline( { since => HTTP::Date::time2str($last_poll) } )
 472       || [];
 473     foreach my $t ( reverse @$tweets ) {
 474         my $text = decode_entities( $t->{text} );
 475         $text =~ s/%/%%/g;
 476         $text =~ s/(^|\W)\@([-\w]+)/$1%B\@$2%n/g;
 477         my $prefix = "";
 478         if (    Irssi::settings_get_bool("show_reply_context")
 479             and $t->{in_reply_to_screen_name} ne $username
 480             and $t->{in_reply_to_screen_name}
 481             and not exists $friends{ $t->{in_reply_to_screen_name} } )
 482         {
 483             $nicks{ $t->{in_reply_to_screen_name} } = time;
 484             my $context = $obj->show_status( $t->{in_reply_to_status_id} );
 485             if ($context) {
 486                 my $ctext = decode_entities( $context->{text} );
 487                 $ctext =~ s/%/%%/g;
 488                 $ctext =~ s/(^|\W)\@([-\w]+)/$1%B\@$2%n/g;
 489                 printf $fh "id:%d [%s%%B\@%s%%n] %s\n",
 490                   $context->{id},
 491                   ( $username ne $user ? "$username: " : "" ),
 492                   $context->{user}{screen_name}, $ctext;
 493                 $prefix = "\--> ";
 494             } else {
 495                 print "Failed to get context from $t->{in_reply_to_screen_name}"
 496                   if &debug;
 497             }
 498         }
 499         next
 500           if $t->{user}{screen_name} eq $username
 501               and not Irssi::settings_get_bool("show_own_tweets");
 502         printf $fh "id:%d %s[%s%%B\@%s%%n] %s\n",
 503           $t->{id},
 504           $prefix,
 505           ( $username ne $user ? "$username: " : "" ),
 506           $t->{user}{screen_name},
 507           $text;
 508     }
 509
 510     print scalar localtime, " - Polling for replies" if &debug;
 511     $tweets = $obj->replies( { since => HTTP::Date::time2str($last_poll) } )
 512       || [];
 513     foreach my $t ( reverse @$tweets ) {
 514         next
 515           if exists $friends{ $t->{user}{screen_name} };
 516
 517         my $text = decode_entities( $t->{text} );
 518         $text =~ s/%/%%/g;
 519         $text =~ s/(^|\W)\@([-\w]+)/$1%B\@$2%n/g;
 520         printf $fh "id:%d [%s%%B\@%s%%n] %s\n",
 521           $t->{id},
 522           ( $username ne $user ? "$username: " : "" ),
 523           $t->{user}{screen_name},
 524           $text;
 525     }
 526
 527     print scalar localtime, " - Polling for DMs" if &debug;
 528     $tweets =
 529       $obj->direct_messages( { since => HTTP::Date::time2str($last_poll) } )
 530       || [];
 531     foreach my $t ( reverse @$tweets ) {
 532         my $text = decode_entities( $t->{text} );
 533         $text =~ s/%/%%/g;
 534         $text =~ s/(^|\W)\@([-\w]+)/$1%B\@$2%n/g;
 535         printf $fh "id:%d [%s%%B\@%s%%n (%%WDM%%n)] %s\n",
 536           $t->{id},
 537           ( $username ne $user ? "$username: " : "" ),
 538           $t->{sender_screen_name},
 539           $text;
 540     }
 541     print scalar localtime, " - Done" if &debug;
 542 }
 543
 544 sub monitor_child {
 545     my $data     = shift;
 546     my $filename = $data->[0];
 547
 548     print scalar localtime, " - checking child log at $filename" if &debug;
 549     my $old_last_poll = $last_poll;
 550     if ( open FILE, $filename ) {
 551         my @lines;
 552         while (<FILE>) {
 553             chomp;
 554             last if /^__friends__/;
 555             if (s/^id:(\d+) //) {
 556                 next if exists $tweet_cache{$1};
 557                 $tweet_cache{$1} = time;
 558             }
 559             push @lines, $_ unless /^__friends__/;
 560         }
 561
 562         %friends = ();
 563         while (<FILE>) {
 564             if (/^\d+$/) {
 565                 $last_poll = $_;
 566                 last;
 567             }
 568             my ( $f, $t ) = split ' ', $_;
 569             $nicks{$f} = $friends{$f} = $t;
 570         }
 571
 572         if ( $last_poll != $old_last_poll ) {
 573             print "new last_poll = $last_poll" if &debug;
 574             foreach my $line (@lines) {
 575                 chomp $line;
 576                 $window->print( $line, MSGLEVEL_PUBLIC );
 577                 foreach ( $line =~ /\@([-\w]+)/ ) {
 578                     $nicks{$1} = time;
 579                 }
 580             }
 581
 582             close FILE;
 583             unlink $filename
 584               or warn "Failed to remove $filename: $!"
 585               unless &debug;
 586
 587       # keep 10 minutes of cached tweets, to make sure we don't show duplicates.
 588             foreach ( keys %tweet_cache ) {
 589                 next if $tweet_cache{$_} > time - 600;
 590                 delete $tweet_cache{$_};
 591             }
 592             return;
 593         }
 594     }
 595
 596     close FILE;
 597     Irssi::timeout_add_once( 5000, 'monitor_child', [$filename] );
 598 }
 599
 600 sub debug {
 601     return Irssi::settings_get_bool("twirssi_debug");
 602 }
 603
 604 sub notice {
 605     $window->print( "%R***%n @_", MSGLEVEL_PUBLIC );
 606 }
 607
 608 sub sig_complete {
 609     my ( $complist, $window, $word, $linestart, $want_space ) = @_;
 610
 611     return unless $linestart =~ /^\/(?:tweet|dm)/;
 612     return if $linestart eq '/tweet' and $word !~ s/^@//;
 613     push @$complist, grep /^\Q$word/i,
 614       sort { $nicks{$b} <=> $nicks{$a} } keys %nicks;
 615     @$complist = map { "\@$_" } @$complist if $linestart eq '/tweet';
 616 }
 617
 618 Irssi::settings_add_str( "twirssi", "twitter_window",     "twitter" );
 619 Irssi::settings_add_str( "twirssi", "bitlbee_server",     "bitlbee" );
 620 Irssi::settings_add_str( "twirssi", "short_url_provider", "TinyURL" );
 621 Irssi::settings_add_str( "twirssi", "twirssi_location",
 622     ".irssi/scripts/twirssi.pl" );
 623 Irssi::settings_add_str( "twirssi", "twitter_usernames", undef );
 624 Irssi::settings_add_str( "twirssi", "twitter_passwords", undef );
 625 Irssi::settings_add_bool( "twirssi", "tweet_to_away",      0 );
 626 Irssi::settings_add_bool( "twirssi", "show_reply_context", 0 );
 627 Irssi::settings_add_bool( "twirssi", "show_own_tweets",    1 );
 628 Irssi::settings_add_bool( "twirssi", "twirssi_debug",      0 );
 629 Irssi::settings_add_bool( "twirssi", "twirssi_first_run",  1 );
 630 $window = Irssi::window_find_name( Irssi::settings_get_str('twitter_window') );
 631
 632 if ($window) {
 633     Irssi::command_bind( "dm",              "cmd_direct" );
 634     Irssi::command_bind( "tweet",           "cmd_tweet" );
 635     Irssi::command_bind( "dm_as",           "cmd_direct_as" );
 636     Irssi::command_bind( "tweet_as",        "cmd_tweet_as" );
 637     Irssi::command_bind( "twitter_login",   "cmd_login" );
 638     Irssi::command_bind( "twitter_logout",  "cmd_logout" );
 639     Irssi::command_bind( "twitter_switch",  "cmd_switch" );
 640     Irssi::command_bind( "twirssi_upgrade", "cmd_upgrade" );
 641     Irssi::command_bind(
 642         "twitter_dump",
 643         sub {
 644             print "twits: ",   Dumper \%twits;
 645             print "friends: ", join ", ", sort keys %friends;
 646             print "nicks: ",   join ", ", sort keys %nicks;
 647             print "last poll: $last_poll";
 648         }
 649     );
 650     Irssi::command_bind(
 651         "twirssi_version",
 652         sub {
 653             &notice(
 654 "Twirssi v$VERSION (r$REV);  Net::Twitter v$Net::Twitter::VERSION. "
 655                   . "See details at http://tinyurl.com/twirssi" );
 656         }
 657     );
 658     Irssi::command_bind(
 659         "twitter_friend",
 660         &gen_cmd(
 661             "/twitter_friend <username>",
 662             "create_friend",
 663             sub { &notice("Following $_[0]"); $nicks{ $_[0] } = time; }
 664         )
 665     );
 666     Irssi::command_bind(
 667         "twitter_unfriend",
 668         &gen_cmd(
 669             "/twitter_unfriend <username>",
 670             "destroy_friend",
 671             sub { &notice("Stopped following $_[0]"); delete $nicks{ $_[0] }; }
 672         )
 673     );
 674     Irssi::command_bind( "twitter_updates", "get_updates" );
 675     Irssi::signal_add_last( 'complete word' => \&sig_complete );
 676
 677     &notice("  %Y<%C(%B^%C)%N                   TWIRSSI v%R$VERSION%N (r$REV)");
 678     &notice("   %C(_(\\%N        http://tinyurl.com/twirssi for full docs");
 679     &notice(
 680         "    %Y||%C `%N Log in with /twitter_login, send updates with /tweet");
 681
 682     if ( my $provider = Irssi::settings_get_str("short_url_provider") ) {
 683         eval "use WWW::Shorten::$provider;";
 684
 685         if ($@) {
 686             &notice(
 687 "Failed to load WWW::Shorten::$provider - either clear short_url_provider or install the CPAN module"
 688             );
 689         }
 690     }
 691
 692     if (    my $autouser = Irssi::settings_get_str("twitter_usernames")
 693         and my $autopass = Irssi::settings_get_str("twitter_passwords") )
 694     {
 695         &cmd_login();
 696     }
 697
 698 } else {
 699     Irssi::active_win()
 700       ->print( "Create a window named "
 701           . Irssi::settings_get_str('twitter_window')
 702           . " or change the value of twitter_window.  Then, reload twirssi." );
 703 }
 704