twirssi.pl

   1 use strict;
   2 use Irssi;
   3 use Irssi::Irc;
   4 use Net::Twitter;
   5 use HTTP::Date;
   6 use HTML::Entities;
   7 use File::Temp;
   8 use LWP::Simple;
   9 use Data::Dumper;
  10 $Data::Dumper::Indent = 1;
  11
  12 use vars qw($VERSION %IRSSI);
  13
  14 $VERSION = "1.5";
  15 my ($REV) = '$Rev: 318 $' =~ /(\d+)/;
  16 %IRSSI = (
  17     authors     => 'Dan Boger',
  18     contact     => 'zigdon@gmail.com',
  19     name        => 'twirssi',
  20     description => 'Send twitter updates using /tweet.  '
  21       . 'Can optionally set your bitlbee /away message to same',
  22     license => 'GNU GPL v2',
  23     url     => 'http://tinyurl.com/twirssi',
  24     changed => 'Mon Dec  1 15:36:01 PST 2008',
  25 );
  26
  27 my $window;
  28 my $twit;
  29 my %twits;
  30 my $user;
  31 my $poll;
  32 my %nicks;
  33 my %friends;
  34 my $last_poll = time - 300;
  35 my %tweet_cache;
  36
  37 sub cmd_direct {
  38     my ( $data, $server, $win ) = @_;
  39
  40     unless ($twit) {
  41         &notice("Not logged in!  Use /twitter_login username pass!");
  42         return;
  43     }
  44
  45     my ( $target, $text ) = split ' ', $data, 2;
  46     unless ( $target and $text ) {
  47         &notice("Usage: /dm <nick> <message>");
  48         return;
  49     }
  50
  51     &cmd_direct_as( "$user $data", $server, $win );
  52 }
  53
  54 sub cmd_direct_as {
  55     my ( $data, $server, $win ) = @_;
  56
  57     unless ($twit) {
  58         &notice("Not logged in!  Use /twitter_login username pass!");
  59         return;
  60     }
  61
  62     my ( $username, $target, $text ) = split ' ', $data, 3;
  63     unless ( $username and $target and $text ) {
  64         &notice("Usage: /dm_as <username> <nick> <message>");
  65         return;
  66     }
  67
  68     unless ( exists $twits{$username} ) {
  69         &notice("Unknown username $username");
  70         return;
  71     }
  72
  73     unless ( $twits{$username}
  74         ->new_direct_message( { user => $target, text => $text } ) )
  75     {
  76         &notice("DM to $target failed");
  77         return;
  78     }
  79
  80     &notice("DM sent to $target");
  81     $nicks{$target} = time;
  82 }
  83
  84 sub cmd_tweet {
  85     my ( $data, $server, $win ) = @_;
  86
  87     unless ($twit) {
  88         &notice("Not logged in!  Use /twitter_login username pass!");
  89         return;
  90     }
  91
  92     $data =~ s/^\s+|\s+$//;
  93     unless ($data) {
  94         &notice("Usage: /tweet <update>");
  95         return;
  96     }
  97
  98     &cmd_tweet_as( "$user $data", $server, $win );
  99 }
 100
 101 sub cmd_tweet_as {
 102     my ( $data, $server, $win ) = @_;
 103
 104     unless ($twit) {
 105         &notice("Not logged in!  Use /twitter_login username pass!");
 106         return;
 107     }
 108
 109     $data =~ s/^\s+|\s+$//;
 110     my ( $username, $data ) = split ' ', $data, 2;
 111
 112     unless ( $username and $data ) {
 113         &notice("Usage: /tweet_as <username> <update>");
 114         return;
 115     }
 116
 117     unless ( exists $twits{$username} ) {
 118         &notice("Unknown username $username");
 119         return;
 120     }
 121
 122     if ( Irssi::settings_get_str("short_url_provider") ) {
 123         foreach my $url ( $data =~ /(https?:\/\/\S+[\w\/])/g ) {
 124             eval {
 125                 my $short = makeashorterlink($url);
 126                 $data =~ s/\Q$url/$short/g;
 127             };
 128         }
 129     }
 130
 131     if ( length $data > 140 ) {
 132         &notice(
 133             "Tweet too long (" . length($data) . " characters) - aborted" );
 134         return;
 135     }
 136
 137     unless ( $twits{$username}->update($data) ) {
 138         &notice("Update failed");
 139         return;
 140     }
 141
 142     foreach ( $data =~ /@([-\w]+)/ ) {
 143         $nicks{$1} = time;
 144     }
 145
 146     my $away = 0;
 147     if (    Irssi::settings_get_bool("tweet_to_away")
 148         and $data !~ /\@\w/
 149         and $data !~ /^[dD] / )
 150     {
 151         my $server =
 152           Irssi::server_find_tag( Irssi::settings_get_str("bitlbee_server") );
 153         if ($server) {
 154             $server->send_raw("away :$data");
 155             $away = 1;
 156         } else {
 157             &notice( "Can't find bitlbee server.",
 158                 "Update bitlbee_server or disalbe tweet_to_away" );
 159         }
 160     }
 161
 162     &notice( "Update sent" . ( $away ? " (and away msg set)" : "" ) );
 163 }
 164
 165 sub gen_cmd {
 166     my ( $usage_str, $api_name, $post_ref ) = @_;
 167
 168     return sub {
 169         my ( $data, $server, $win ) = @_;
 170
 171         unless ($twit) {
 172             &notice("Not logged in!  Use /twitter_login username pass!");
 173             return;
 174         }
 175
 176         $data =~ s/^\s+|\s+$//;
 177         unless ($data) {
 178             &notice("Usage: $usage_str");
 179             return;
 180         }
 181
 182         unless ( $twit->$api_name($data) ) {
 183             &notice("$api_name failed");
 184             return;
 185         }
 186
 187         &$post_ref($data) if $post_ref;
 188       }
 189 }
 190
 191 sub cmd_switch {
 192     my ( $data, $server, $win ) = @_;
 193
 194     $data =~ s/^\s+|\s+$//g;
 195     if ( exists $twits{$data} ) {
 196         &notice("Switching to $data");
 197         $twit = $twits{$data};
 198         $user = $data;
 199     } else {
 200         &notice("Unknown user $data");
 201     }
 202 }
 203
 204 sub cmd_logout {
 205     my ( $data, $server, $win ) = @_;
 206
 207     $data =~ s/^\s+|\s+$//g;
 208     if ( $data and exists $twits{$data} ) {
 209         &notice("Logging out $data...");
 210         $twits{$data}->end_session();
 211         delete $twits{$data};
 212     } elsif ($data) {
 213         &notice("Unknown username '$data'");
 214     } else {
 215         &notice("Logging out $user...");
 216         $twit->end_session();
 217         undef $twit;
 218         delete $twits{$user};
 219         if ( keys %twits ) {
 220             &cmd_switch( ( keys %twits )[0], $server, $win );
 221         } else {
 222             Irssi::timeout_remove($poll) if $poll;
 223             undef $poll;
 224         }
 225     }
 226 }
 227
 228 sub cmd_login {
 229     my ( $data, $server, $win ) = @_;
 230     my $pass;
 231     if ($data) {
 232         ( $user, $pass ) = split ' ', $data, 2;
 233     } elsif ( my $autouser = Irssi::settings_get_str("twitter_usernames")
 234         and my $autopass = Irssi::settings_get_str("twitter_passwords") )
 235     {
 236         my @user = split /\s*,\s*/, $autouser;
 237         my @pass = split /\s*,\s*/, $autopass;
 238         if ( @user != @pass ) {
 239             &notice("Number of usernames doesn't match "
 240                   . "the number of passwords - auto-login failed" );
 241         } else {
 242             my ( $u, $p );
 243             while ( @user and @pass ) {
 244                 $u = shift @user;
 245                 $p = shift @pass;
 246                 &cmd_login("$u $p");
 247             }
 248         }
 249     } else {
 250         &notice("/twitter_login requires either a username and password "
 251               . "or twitter_usernames and twitter_passwords to be set." );
 252         return;
 253     }
 254
 255     %friends = %nicks = ();
 256
 257     $twit = Net::Twitter->new(
 258         username => $user,
 259         password => $pass,
 260         source   => "twirssi"
 261     );
 262
 263     unless ( $twit->verify_credentials() ) {
 264         &notice("Login as $user failed");
 265         $twit = undef;
 266         if ( keys %twits ) {
 267             &cmd_switch( ( keys %twits )[0], $server, $win );
 268         }
 269         return;
 270     }
 271
 272     if ($twit) {
 273         my $rate_limit = $twit->rate_limit_status();
 274         if ( $rate_limit and $rate_limit->{remaining_hits} < 1 ) {
 275             &notice("Rate limit exceeded, try again later");
 276             $twit = undef;
 277             return;
 278         }
 279
 280         $twits{$user} = $twit;
 281         Irssi::timeout_remove($poll) if $poll;
 282         $poll = Irssi::timeout_add( 300 * 1000, \&get_updates, "" );
 283         &notice("Logged in as $user, loading friends list...");
 284         &load_friends;
 285         &notice( "loaded friends: ", scalar keys %friends );
 286         if ( Irssi::settings_get_bool("twirssi_first_run") ) {
 287             Irssi::settings_set_bool( "twirssi_first_run", 0 );
 288             unless ( exists $friends{twirssi} ) {
 289                 &notice("Welcome to twirssi!"
 290                       . "  Perhaps you should add \@twirssi to your friends list,"
 291                       . " so you can be notified when a new version is release?"
 292                       . "  Just type /twitter_friend twirssi." );
 293             }
 294         }
 295         %nicks = %friends;
 296         $nicks{$user} = 0;
 297         &get_updates;
 298     } else {
 299         &notice("Login failed");
 300     }
 301 }
 302
 303 sub cmd_upgrade {
 304     my ( $data, $server, $win ) = @_;
 305
 306     my $loc = Irssi::settings_get_str("twirssi_location");
 307     unless ( -w $loc ) {
 308         &notice(
 309 "$loc isn't writable, can't upgrade.  Perhaps you need to /set twirssi_location?"
 310         );
 311         return;
 312     }
 313
 314     if ( not -x "/usr/bin/md5sum" and not $data ) {
 315         &notice(
 316 "/usr/bin/md5sum can't be found - try '/twirssi_upgrade nomd5' to skip MD5 verification"
 317         );
 318         return;
 319     }
 320
 321     my $md5;
 322     unless ($data) {
 323         eval { use Digest::MD5; };
 324
 325         if ($@) {
 326             &notice(
 327 "Failed to load Digest::MD5.  Try '/twirssi_upgrade nomd5' to skip MD5 verification"
 328             );
 329             return;
 330         }
 331
 332         $md5 = get("http://irc.peeron.com/~zigdon/twirssi/md5sum");
 333         chomp $md5;
 334         $md5 =~ s/ .*//;
 335         unless ($md5) {
 336             &notice("Failed to download md5sum from peeron!  Aborting.");
 337             return;
 338         }
 339
 340         unless ( open( CUR, $loc ) ) {
 341             &notice(
 342 "Failed to read $loc.  Check that /set twirssi_location is set to the correct location."
 343             );
 344             return;
 345         }
 346
 347         my $cur_md5 = Digest::MD5::md5_hex(<CUR>);
 348         close CUR;
 349
 350         if ( $cur_md5 eq $md5 ) {
 351             &notice("Current twirssi seems to be up to date.");
 352             return;
 353         }
 354     }
 355
 356     my $URL = "http://irc.peeron.com/~zigdon/twirssi/twirssi.pl";
 357     &notice("Downloading twirssi from $URL");
 358     LWP::Simple::getstore( $URL, "$loc.upgrade" );
 359
 360     unless ($data) {
 361         unless ( open( NEW, "$loc.upgrade" ) ) {
 362             &notice(
 363 "Failed to read $loc.upgrade.  Check that /set twirssi_location is set to the correct location."
 364             );
 365             return;
 366         }
 367
 368         my $new_md5 = Digest::MD5::md5_hex(<NEW>);
 369         close NEW;
 370
 371         if ( $new_md5 ne $md5 ) {
 372             &notice("MD5 verification failed. expected $md5, got $new_md5");
 373             return;
 374         }
 375     }
 376
 377     rename $loc, "$loc.backup"
 378       or &notice("Failed to back up $loc: $!.  Aborting")
 379       and return;
 380     rename "$loc.upgrade", $loc
 381       or &notice("Failed to rename $loc.upgrade: $!.  Aborting")
 382       and return;
 383
 384     my ( $dir, $file ) = ( $loc =~ m{(.*)/([^/]+)$} );
 385     if ( -e "$dir/autorun/$file" ) {
 386         &notice("Updating $dir/autorun/$file");
 387         unlink "$dir/autorun/$file"
 388           or &notice("Failed to remove old $file from autorun: $!");
 389         symlink "../$file", "$dir/autorun/$file"
 390           or &notice("Failed to create symlink in autorun directory: $!");
 391     }
 392
 393     &notice("Download complete.  Reload twirssi with /script load $file");
 394 }
 395
 396 sub load_friends {
 397     my $page = 1;
 398     my %new_friends;
 399     while (1) {
 400         my $friends = $twit->friends( { page => $page } );
 401         last unless $friends;
 402         $new_friends{ $_->{screen_name} } = time foreach @$friends;
 403         $page++;
 404         last if @$friends == 0 or $page == 10;
 405         $friends = $twit->friends( page => $page );
 406     }
 407
 408     foreach ( keys %new_friends ) {
 409         next if exists $friends{$_};
 410         $friends{$_} = time;
 411     }
 412
 413     foreach ( keys %friends ) {
 414         delete $friends{$_} unless exists $new_friends{$_};
 415     }
 416 }
 417
 418 sub get_updates {
 419     print scalar localtime, " - get_updates starting" if &debug;
 420
 421     $window =
 422       Irssi::window_find_name( Irssi::settings_get_str('twitter_window') );
 423     unless ($window) {
 424         Irssi::active_win()
 425           ->print( "Can't find a window named '"
 426               . Irssi::settings_get_str('twitter_window')
 427               . "'.  Create it or change the value of twitter_window" );
 428     }
 429     unless ($twit) {
 430         &notice("Not logged in!  Use /twitter_login username pass!");
 431         return;
 432     }
 433
 434     my ( $fh, $filename ) = File::Temp::tempfile();
 435     my $pid = fork();
 436
 437     if ($pid) {    # parent
 438         Irssi::timeout_add_once( 5000, 'monitor_child', [$filename] );
 439     } elsif ( defined $pid ) {    # child
 440         close STDIN;
 441         close STDOUT;
 442         close STDERR;
 443
 444         my $new_poll = time;
 445
 446         &do_updates( $fh, $user, $twit );
 447         foreach ( keys %twits ) {
 448             next if $_ eq $user;
 449             &do_updates( $fh, $_, $twits{$_} );
 450         }
 451
 452         print $fh "__friends__\n";
 453         &load_friends;
 454         foreach ( sort keys %friends ) {
 455             print $fh "$_ $friends{$_}\n";
 456         }
 457         print $fh $new_poll;
 458         close $fh;
 459         exit;
 460     }
 461     print scalar localtime, " - get_updates ends" if &debug;
 462 }
 463
 464 sub do_updates {
 465     my ( $fh, $username, $obj ) = @_;
 466
 467     print scalar localtime, " - Polling for updates for $username" if &debug;
 468     my $tweets =
 469       $obj->friends_timeline( { since => HTTP::Date::time2str($last_poll) } )
 470       || [];
 471     foreach my $t ( reverse @$tweets ) {
 472         my $text = decode_entities( $t->{text} );
 473         $text =~ s/%/%%/g;
 474         $text =~ s/(^|\W)\@([-\w]+)/$1%B\@$2%n/g;
 475         my $prefix = "";
 476         if (    Irssi::settings_get_bool("show_reply_context")
 477             and $t->{in_reply_to_screen_name} ne $username
 478             and $t->{in_reply_to_screen_name}
 479             and not exists $friends{ $t->{in_reply_to_screen_name} } )
 480         {
 481             $nicks{ $t->{in_reply_to_screen_name} } = time;
 482             my $context = $obj->show_status( $t->{in_reply_to_status_id} );
 483             if ($context) {
 484                 my $ctext = decode_entities( $context->{text} );
 485                 $ctext =~ s/%/%%/g;
 486                 $ctext =~ s/(^|\W)\@([-\w]+)/$1%B\@$2%n/g;
 487                 printf $fh "id:%d [%s%%B\@%s%%n] %s\n",
 488                   $context->{id},
 489                   ( $username ne $user ? "$username: " : "" ),
 490                   $context->{user}{screen_name}, $ctext;
 491                 $prefix = "\--> ";
 492             } else {
 493                 print "Failed to get context from $t->{in_reply_to_screen_name}"
 494                   if &debug;
 495             }
 496         }
 497         next
 498           if $t->{user}{screen_name} eq $username
 499               and not Irssi::settings_get_bool("show_own_tweets");
 500         printf $fh "id:%d %s[%s%%B\@%s%%n] %s\n",
 501           $t->{id},
 502           $prefix,
 503           ( $username ne $user ? "$username: " : "" ),
 504           $t->{user}{screen_name},
 505           $text;
 506     }
 507
 508     print scalar localtime, " - Polling for replies" if &debug;
 509     $tweets = $obj->replies( { since => HTTP::Date::time2str($last_poll) } )
 510       || [];
 511     foreach my $t ( reverse @$tweets ) {
 512         next
 513           if exists $friends{ $t->{user}{screen_name} };
 514
 515         my $text = decode_entities( $t->{text} );
 516         $text =~ s/%/%%/g;
 517         $text =~ s/(^|\W)\@([-\w]+)/$1%B\@$2%n/g;
 518         printf $fh "id:%d [%s%%B\@%s%%n] %s\n",
 519           $t->{id},
 520           ( $username ne $user ? "$username: " : "" ),
 521           $t->{user}{screen_name},
 522           $text;
 523     }
 524
 525     print scalar localtime, " - Polling for DMs" if &debug;
 526     $tweets =
 527       $obj->direct_messages( { since => HTTP::Date::time2str($last_poll) } )
 528       || [];
 529     foreach my $t ( reverse @$tweets ) {
 530         my $text = decode_entities( $t->{text} );
 531         $text =~ s/%/%%/g;
 532         $text =~ s/(^|\W)\@([-\w]+)/$1%B\@$2%n/g;
 533         printf $fh "id:%d [%s%%B\@%s%%n (%%WDM%%n)] %s\n",
 534           $t->{id},
 535           ( $username ne $user ? "$username: " : "" ),
 536           $t->{sender_screen_name},
 537           $text;
 538     }
 539     print scalar localtime, " - Done" if &debug;
 540 }
 541
 542 sub monitor_child {
 543     my $data     = shift;
 544     my $filename = $data->[0];
 545
 546     print scalar localtime, " - checking child log at $filename" if &debug;
 547     my $old_last_poll = $last_poll;
 548     if ( open FILE, $filename ) {
 549         my @lines;
 550         while (<FILE>) {
 551             chomp;
 552             last if /^__friends__/;
 553             if (s/^id:(\d+) //) {
 554                 next if exists $tweet_cache{$1};
 555                 $tweet_cache{$1} = time;
 556             }
 557             push @lines, $_ unless /^__friends__/;
 558         }
 559
 560         %friends = ();
 561         while (<FILE>) {
 562             if (/^\d+$/) {
 563                 $last_poll = $_;
 564                 last;
 565             }
 566             my ( $f, $t ) = split ' ', $_;
 567             $nicks{$f} = $friends{$f} = $t;
 568         }
 569
 570         if ( $last_poll != $old_last_poll ) {
 571             print "new last_poll = $last_poll" if &debug;
 572             foreach my $line (@lines) {
 573                 chomp $line;
 574                 $window->print( $line, MSGLEVEL_PUBLIC );
 575                 foreach ( $line =~ /\@([-\w]+)/ ) {
 576                     $nicks{$1} = time;
 577                 }
 578             }
 579
 580             close FILE;
 581             unlink $filename
 582               or warn "Failed to remove $filename: $!"
 583               unless &debug;
 584
 585       # keep 10 minutes of cached tweets, to make sure we don't show duplicates.
 586             foreach ( keys %tweet_cache ) {
 587                 next if $tweet_cache{$_} > time - 600;
 588                 delete $tweet_cache{$_};
 589             }
 590             return;
 591         }
 592     }
 593
 594     close FILE;
 595     Irssi::timeout_add_once( 5000, 'monitor_child', [$filename] );
 596 }
 597
 598 sub debug {
 599     return Irssi::settings_get_bool("twirssi_debug");
 600 }
 601
 602 sub notice {
 603     $window->print( "%R***%n @_", MSGLEVEL_PUBLIC );
 604 }
 605
 606 sub sig_complete {
 607     my ( $complist, $window, $word, $linestart, $want_space ) = @_;
 608
 609     return unless $linestart =~ /^\/(?:tweet|dm)/;
 610     return if $linestart eq '/tweet' and $word !~ s/^@//;
 611     push @$complist, grep /^\Q$word/i,
 612       sort { $nicks{$b} <=> $nicks{$a} } keys %nicks;
 613     @$complist = map { "\@$_" } @$complist if $linestart eq '/tweet';
 614 }
 615
 616 Irssi::settings_add_str( "twirssi", "twitter_window",     "twitter" );
 617 Irssi::settings_add_str( "twirssi", "bitlbee_server",     "bitlbee" );
 618 Irssi::settings_add_str( "twirssi", "short_url_provider", "TinyURL" );
 619 Irssi::settings_add_str( "twirssi", "twirssi_location",
 620     ".irssi/scripts/twirssi.pl" );
 621 Irssi::settings_add_str( "twirssi", "twitter_usernames", undef );
 622 Irssi::settings_add_str( "twirssi", "twitter_passwords", undef );
 623 Irssi::settings_add_bool( "twirssi", "tweet_to_away",      0 );
 624 Irssi::settings_add_bool( "twirssi", "show_reply_context", 0 );
 625 Irssi::settings_add_bool( "twirssi", "show_own_tweets",    1 );
 626 Irssi::settings_add_bool( "twirssi", "twirssi_debug",      0 );
 627 Irssi::settings_add_bool( "twirssi", "twirssi_first_run",  1 );
 628 $window = Irssi::window_find_name( Irssi::settings_get_str('twitter_window') );
 629
 630 if ($window) {
 631     Irssi::command_bind( "dm",              "cmd_direct" );
 632     Irssi::command_bind( "tweet",           "cmd_tweet" );
 633     Irssi::command_bind( "dm_as",           "cmd_direct_as" );
 634     Irssi::command_bind( "tweet_as",        "cmd_tweet_as" );
 635     Irssi::command_bind( "twitter_login",   "cmd_login" );
 636     Irssi::command_bind( "twitter_logout",  "cmd_logout" );
 637     Irssi::command_bind( "twitter_switch",  "cmd_switch" );
 638     Irssi::command_bind( "twirssi_upgrade", "cmd_upgrade" );
 639     Irssi::command_bind(
 640         "twitter_dump",
 641         sub {
 642             print "twits: ",   Dumper \%twits;
 643             print "friends: ", join ", ", sort keys %friends;
 644             print "nicks: ",   join ", ", sort keys %nicks;
 645             print "last poll: $last_poll";
 646         }
 647     );
 648     Irssi::command_bind(
 649         "twirssi_version",
 650         sub {
 651             &notice(
 652 "Twirssi v$VERSION (r$REV);  Net::Twitter v$Net::Twitter::VERSION. "
 653                   . "See details at http://tinyurl.com/twirssi" );
 654         }
 655     );
 656     Irssi::command_bind(
 657         "twitter_friend",
 658         &gen_cmd(
 659             "/twitter_friend <username>",
 660             "create_friend",
 661             sub { &notice("Following $_[0]"); $nicks{ $_[0] } = time; }
 662         )
 663     );
 664     Irssi::command_bind(
 665         "twitter_unfriend",
 666         &gen_cmd(
 667             "/twitter_unfriend <username>",
 668             "destroy_friend",
 669             sub { &notice("Stopped following $_[0]"); delete $nicks{ $_[0] }; }
 670         )
 671     );
 672     Irssi::command_bind( "twitter_updates", "get_updates" );
 673     Irssi::signal_add_last( 'complete word' => \&sig_complete );
 674
 675     &notice("  %Y<%C(%B^%C)%N                   TWIRSSI v%R$VERSION%N (r$REV)");
 676     &notice("   %C(_(\\%N        http://tinyurl.com/twirssi for full docs");
 677     &notice(
 678         "    %Y||%C `%N Log in with /twitter_login, send updates with /tweet");
 679
 680     if ( my $provider = Irssi::settings_get_str("short_url_provider") ) {
 681         eval "use WWW::Shorten::$provider;";
 682
 683         if ($@) {
 684             &notice(
 685 "Failed to load WWW::Shorten::$provider - either clear short_url_provider or install the CPAN module"
 686             );
 687         }
 688     }
 689
 690     if (    my $autouser = Irssi::settings_get_str("twitter_usernames")
 691         and my $autopass = Irssi::settings_get_str("twitter_passwords") )
 692     {
 693         &cmd_login();
 694     }
 695
 696 } else {
 697     Irssi::active_win()
 698       ->print( "Create a window named "
 699           . Irssi::settings_get_str('twitter_window')
 700           . " or change the value of twitter_window.  Then, reload twirssi." );
 701 }
 702