twirssi.pl

   1 use strict;
   2 use Irssi;
   3 use Irssi::Irc;
   4 use Net::Twitter;
   5 use HTTP::Date;
   6 use HTML::Entities;
   7 use File::Temp;
   8 use LWP::Simple;
   9 use Data::Dumper;
  10 $Data::Dumper::Indent = 1;
  11
  12 use vars qw($VERSION %IRSSI);
  13
  14 $VERSION = "1.5.3";
  15 my ($REV) = '$Rev: 331 $' =~ /(\d+)/;
  16 %IRSSI = (
  17     authors     => 'Dan Boger',
  18     contact     => 'zigdon@gmail.com',
  19     name        => 'twirssi',
  20     description => 'Send twitter updates using /tweet.  '
  21       . 'Can optionally set your bitlbee /away message to same',
  22     license => 'GNU GPL v2',
  23     url     => 'http://tinyurl.com/twirssi',
  24     changed => 'Mon Dec  1 15:36:01 PST 2008',
  25 );
  26
  27 my $window;
  28 my $twit;
  29 my %twits;
  30 my $user;
  31 my $poll;
  32 my %nicks;
  33 my %friends;
  34 my $last_poll = time - 300;
  35 my %tweet_cache;
  36
  37 sub cmd_direct {
  38     my ( $data, $server, $win ) = @_;
  39
  40     unless ($twit) {
  41         &notice("Not logged in!  Use /twitter_login username pass!");
  42         return;
  43     }
  44
  45     my ( $target, $text ) = split ' ', $data, 2;
  46     unless ( $target and $text ) {
  47         &notice("Usage: /dm <nick> <message>");
  48         return;
  49     }
  50
  51     &cmd_direct_as( "$user $data", $server, $win );
  52 }
  53
  54 sub cmd_direct_as {
  55     my ( $data, $server, $win ) = @_;
  56
  57     unless ($twit) {
  58         &notice("Not logged in!  Use /twitter_login username pass!");
  59         return;
  60     }
  61
  62     my ( $username, $target, $text ) = split ' ', $data, 3;
  63     unless ( $username and $target and $text ) {
  64         &notice("Usage: /dm_as <username> <nick> <message>");
  65         return;
  66     }
  67
  68     unless ( exists $twits{$username} ) {
  69         &notice("Unknown username $username");
  70         return;
  71     }
  72
  73     unless ( $twits{$username}
  74         ->new_direct_message( { user => $target, text => $text } ) )
  75     {
  76         &notice("DM to $target failed");
  77         return;
  78     }
  79
  80     &notice("DM sent to $target");
  81     $nicks{$target} = time;
  82 }
  83
  84 sub cmd_tweet {
  85     my ( $data, $server, $win ) = @_;
  86
  87     unless ($twit) {
  88         &notice("Not logged in!  Use /twitter_login username pass!");
  89         return;
  90     }
  91
  92     $data =~ s/^\s+|\s+$//;
  93     unless ($data) {
  94         &notice("Usage: /tweet <update>");
  95         return;
  96     }
  97
  98     &cmd_tweet_as( "$user $data", $server, $win );
  99 }
 100
 101 sub cmd_tweet_as {
 102     my ( $data, $server, $win ) = @_;
 103
 104     unless ($twit) {
 105         &notice("Not logged in!  Use /twitter_login username pass!");
 106         return;
 107     }
 108
 109     $data =~ s/^\s+|\s+$//;
 110     my ( $username, $data ) = split ' ', $data, 2;
 111
 112     unless ( $username and $data ) {
 113         &notice("Usage: /tweet_as <username> <update>");
 114         return;
 115     }
 116
 117     unless ( exists $twits{$username} ) {
 118         &notice("Unknown username $username");
 119         return;
 120     }
 121
 122     if ( Irssi::settings_get_str("short_url_provider") ) {
 123         foreach my $url ( $data =~ /(https?:\/\/\S+[\w\/])/g ) {
 124             eval {
 125                 my $short = makeashorterlink($url);
 126                 $data =~ s/\Q$url/$short/g;
 127             };
 128         }
 129     }
 130
 131     if ( length $data > 140 ) {
 132         &notice(
 133             "Tweet too long (" . length($data) . " characters) - aborted" );
 134         return;
 135     }
 136
 137     unless ( $twits{$username}->update($data) ) {
 138         &notice("Update failed");
 139         return;
 140     }
 141
 142     foreach ( $data =~ /@([-\w]+)/ ) {
 143         $nicks{$1} = time;
 144     }
 145
 146     my $away = 0;
 147     if (    Irssi::settings_get_bool("tweet_to_away")
 148         and $data !~ /\@\w/
 149         and $data !~ /^[dD] / )
 150     {
 151         my $server =
 152           Irssi::server_find_tag( Irssi::settings_get_str("bitlbee_server") );
 153         if ($server) {
 154             $server->send_raw("away :$data");
 155             $away = 1;
 156         } else {
 157             &notice( "Can't find bitlbee server.",
 158                 "Update bitlbee_server or disalbe tweet_to_away" );
 159         }
 160     }
 161
 162     &notice( "Update sent" . ( $away ? " (and away msg set)" : "" ) );
 163 }
 164
 165 sub gen_cmd {
 166     my ( $usage_str, $api_name, $post_ref ) = @_;
 167
 168     return sub {
 169         my ( $data, $server, $win ) = @_;
 170
 171         unless ($twit) {
 172             &notice("Not logged in!  Use /twitter_login username pass!");
 173             return;
 174         }
 175
 176         $data =~ s/^\s+|\s+$//;
 177         unless ($data) {
 178             &notice("Usage: $usage_str");
 179             return;
 180         }
 181
 182         unless ( $twit->$api_name($data) ) {
 183             &notice("$api_name failed");
 184             return;
 185         }
 186
 187         &$post_ref($data) if $post_ref;
 188       }
 189 }
 190
 191 sub cmd_switch {
 192     my ( $data, $server, $win ) = @_;
 193
 194     $data =~ s/^\s+|\s+$//g;
 195     if ( exists $twits{$data} ) {
 196         &notice("Switching to $data");
 197         $twit = $twits{$data};
 198         $user = $data;
 199     } else {
 200         &notice("Unknown user $data");
 201     }
 202 }
 203
 204 sub cmd_logout {
 205     my ( $data, $server, $win ) = @_;
 206
 207     $data =~ s/^\s+|\s+$//g;
 208     if ( $data and exists $twits{$data} ) {
 209         &notice("Logging out $data...");
 210         $twits{$data}->end_session();
 211         delete $twits{$data};
 212     } elsif ($data) {
 213         &notice("Unknown username '$data'");
 214     } else {
 215         &notice("Logging out $user...");
 216         $twit->end_session();
 217         undef $twit;
 218         delete $twits{$user};
 219         if ( keys %twits ) {
 220             &cmd_switch( ( keys %twits )[0], $server, $win );
 221         } else {
 222             Irssi::timeout_remove($poll) if $poll;
 223             undef $poll;
 224         }
 225     }
 226 }
 227
 228 sub cmd_login {
 229     my ( $data, $server, $win ) = @_;
 230     my $pass;
 231     if ($data) {
 232         ( $user, $pass ) = split ' ', $data, 2;
 233     } elsif ( my $autouser = Irssi::settings_get_str("twitter_usernames")
 234         and my $autopass = Irssi::settings_get_str("twitter_passwords") )
 235     {
 236         my @user = split /\s*,\s*/, $autouser;
 237         my @pass = split /\s*,\s*/, $autopass;
 238         if ( @user != @pass ) {
 239             &notice("Number of usernames doesn't match "
 240                   . "the number of passwords - auto-login failed" );
 241         } else {
 242             my ( $u, $p );
 243             while ( @user and @pass ) {
 244                 $u = shift @user;
 245                 $p = shift @pass;
 246                 &cmd_login("$u $p");
 247             }
 248             return;
 249         }
 250     } else {
 251         &notice("/twitter_login requires either a username and password "
 252               . "or twitter_usernames and twitter_passwords to be set." );
 253         return;
 254     }
 255
 256     %friends = %nicks = ();
 257
 258     $twit = Net::Twitter->new(
 259         username => $user,
 260         password => $pass,
 261         source   => "twirssi"
 262     );
 263
 264     unless ( $twit->verify_credentials() ) {
 265         &notice("Login as $user failed");
 266         $twit = undef;
 267         if ( keys %twits ) {
 268             &cmd_switch( ( keys %twits )[0], $server, $win );
 269         }
 270         return;
 271     }
 272
 273     if ($twit) {
 274         my $rate_limit = $twit->rate_limit_status();
 275         if ( $rate_limit and $rate_limit->{remaining_hits} < 1 ) {
 276             &notice("Rate limit exceeded, try again later");
 277             $twit = undef;
 278             return;
 279         }
 280
 281         $twits{$user} = $twit;
 282         Irssi::timeout_remove($poll) if $poll;
 283         $poll = Irssi::timeout_add( 300 * 1000, \&get_updates, "" );
 284         &notice("Logged in as $user, loading friends list...");
 285         &load_friends;
 286         &notice( "loaded friends: ", scalar keys %friends );
 287         if ( Irssi::settings_get_bool("twirssi_first_run") ) {
 288             Irssi::settings_set_bool( "twirssi_first_run", 0 );
 289             unless ( exists $friends{twirssi} ) {
 290                 &notice("Welcome to twirssi!"
 291                       . "  Perhaps you should add \@twirssi to your friends list,"
 292                       . " so you can be notified when a new version is release?"
 293                       . "  Just type /twitter_friend twirssi." );
 294             }
 295         }
 296         %nicks = %friends;
 297         $nicks{$user} = 0;
 298         &get_updates;
 299     } else {
 300         &notice("Login failed");
 301     }
 302 }
 303
 304 sub cmd_upgrade {
 305     my ( $data, $server, $win ) = @_;
 306
 307     my $loc = Irssi::settings_get_str("twirssi_location");
 308     unless ( -w $loc ) {
 309         &notice(
 310 "$loc isn't writable, can't upgrade.  Perhaps you need to /set twirssi_location?"
 311         );
 312         return;
 313     }
 314
 315     if ( not -x "/usr/bin/md5sum" and not $data ) {
 316         &notice(
 317 "/usr/bin/md5sum can't be found - try '/twirssi_upgrade nomd5' to skip MD5 verification"
 318         );
 319         return;
 320     }
 321
 322     my $md5;
 323     unless ($data) {
 324         eval { use Digest::MD5; };
 325
 326         if ($@) {
 327             &notice(
 328 "Failed to load Digest::MD5.  Try '/twirssi_upgrade nomd5' to skip MD5 verification"
 329             );
 330             return;
 331         }
 332
 333         $md5 = get("http://irc.peeron.com/~zigdon/twirssi/md5sum");
 334         chomp $md5;
 335         $md5 =~ s/ .*//;
 336         unless ($md5) {
 337             &notice("Failed to download md5sum from peeron!  Aborting.");
 338             return;
 339         }
 340
 341         unless ( open( CUR, $loc ) ) {
 342             &notice(
 343 "Failed to read $loc.  Check that /set twirssi_location is set to the correct location."
 344             );
 345             return;
 346         }
 347
 348         my $cur_md5 = Digest::MD5::md5_hex(<CUR>);
 349         close CUR;
 350
 351         if ( $cur_md5 eq $md5 ) {
 352             &notice("Current twirssi seems to be up to date.");
 353             return;
 354         }
 355     }
 356
 357     my $URL = "http://irc.peeron.com/~zigdon/twirssi/twirssi.pl";
 358     &notice("Downloading twirssi from $URL");
 359     LWP::Simple::getstore( $URL, "$loc.upgrade" );
 360
 361     unless ($data) {
 362         unless ( open( NEW, "$loc.upgrade" ) ) {
 363             &notice(
 364 "Failed to read $loc.upgrade.  Check that /set twirssi_location is set to the correct location."
 365             );
 366             return;
 367         }
 368
 369         my $new_md5 = Digest::MD5::md5_hex(<NEW>);
 370         close NEW;
 371
 372         if ( $new_md5 ne $md5 ) {
 373             &notice("MD5 verification failed. expected $md5, got $new_md5");
 374             return;
 375         }
 376     }
 377
 378     rename $loc, "$loc.backup"
 379       or &notice("Failed to back up $loc: $!.  Aborting")
 380       and return;
 381     rename "$loc.upgrade", $loc
 382       or &notice("Failed to rename $loc.upgrade: $!.  Aborting")
 383       and return;
 384
 385     my ( $dir, $file ) = ( $loc =~ m{(.*)/([^/]+)$} );
 386     if ( -e "$dir/autorun/$file" ) {
 387         &notice("Updating $dir/autorun/$file");
 388         unlink "$dir/autorun/$file"
 389           or &notice("Failed to remove old $file from autorun: $!");
 390         symlink "../$file", "$dir/autorun/$file"
 391           or &notice("Failed to create symlink in autorun directory: $!");
 392     }
 393
 394     &notice("Download complete.  Reload twirssi with /script load $file");
 395 }
 396
 397 sub load_friends {
 398     my $page = 1;
 399     my %new_friends;
 400     while (1) {
 401         my $friends = $twit->friends( { page => $page } );
 402         last unless $friends;
 403         $new_friends{ $_->{screen_name} } = time foreach @$friends;
 404         $page++;
 405         last if @$friends == 0 or $page == 10;
 406         $friends = $twit->friends( page => $page );
 407     }
 408
 409     my ($added, $removed) = (0, 0);
 410     foreach ( keys %new_friends ) {
 411         next if exists $friends{$_};
 412         $friends{$_} = time;
 413         $added++;
 414     }
 415
 416     foreach ( keys %friends ) {
 417         next if exists $new_friends{$_};
 418         delete $friends{$_};
 419         $removed++;
 420     }
 421
 422     return ($added, $removed);
 423 }
 424
 425 sub get_updates {
 426     print scalar localtime, " - get_updates starting" if &debug;
 427
 428     $window =
 429       Irssi::window_find_name( Irssi::settings_get_str('twitter_window') );
 430     unless ($window) {
 431         Irssi::active_win()
 432           ->print( "Can't find a window named '"
 433               . Irssi::settings_get_str('twitter_window')
 434               . "'.  Create it or change the value of twitter_window" );
 435     }
 436     unless ($twit) {
 437         &notice("Not logged in!  Use /twitter_login username pass!");
 438         return;
 439     }
 440
 441     my ( $fh, $filename ) = File::Temp::tempfile();
 442     my $pid = fork();
 443
 444     if ($pid) {    # parent
 445         Irssi::timeout_add_once( 5000, 'monitor_child', [$filename] );
 446         Irssi::pidwait_add($pid);
 447     } elsif ( defined $pid ) {    # child
 448         close STDIN;
 449         close STDOUT;
 450         close STDERR;
 451
 452         my $new_poll = time;
 453
 454         &do_updates( $fh, $user, $twit );
 455         foreach ( keys %twits ) {
 456             next if $_ eq $user;
 457             &do_updates( $fh, $_, $twits{$_} );
 458         }
 459
 460         my ($added, $removed) = &load_friends;
 461         if ($added + $removed) {
 462           print $fh "%R***%n Friends list updated: ",
 463                     join(", ", sprintf("%d added", $added),
 464                                sprintf("%d removed", $removed)), "\n";
 465         }
 466         print $fh "__friends__\n";
 467         foreach ( sort keys %friends ) {
 468             print $fh "$_ $friends{$_}\n";
 469         }
 470         print $fh $new_poll;
 471         close $fh;
 472         exit;
 473     }
 474     print scalar localtime, " - get_updates ends" if &debug;
 475 }
 476
 477 sub do_updates {
 478     my ( $fh, $username, $obj ) = @_;
 479
 480     print scalar localtime, " - Polling for updates for $username" if &debug;
 481     my $tweets =
 482       $obj->friends_timeline( { since => HTTP::Date::time2str($last_poll) } )
 483       || [];
 484     foreach my $t ( reverse @$tweets ) {
 485         my $text = decode_entities( $t->{text} );
 486         $text =~ s/%/%%/g;
 487         $text =~ s/(^|\W)\@([-\w]+)/$1%B\@$2%n/g;
 488         my $prefix = "";
 489         if (    Irssi::settings_get_bool("show_reply_context")
 490             and $t->{in_reply_to_screen_name} ne $username
 491             and $t->{in_reply_to_screen_name}
 492             and not exists $friends{ $t->{in_reply_to_screen_name} } )
 493         {
 494             $nicks{ $t->{in_reply_to_screen_name} } = time;
 495             my $context = $obj->show_status( $t->{in_reply_to_status_id} );
 496             if ($context) {
 497                 my $ctext = decode_entities( $context->{text} );
 498                 $ctext =~ s/%/%%/g;
 499                 $ctext =~ s/(^|\W)\@([-\w]+)/$1%B\@$2%n/g;
 500                 printf $fh "id:%d [%s%%B\@%s%%n] %s\n",
 501                   $context->{id},
 502                   ( $username ne $user ? "$username: " : "" ),
 503                   $context->{user}{screen_name}, $ctext;
 504                 $prefix = "\--> ";
 505             } else {
 506                 print "Failed to get context from $t->{in_reply_to_screen_name}"
 507                   if &debug;
 508             }
 509         }
 510         next
 511           if $t->{user}{screen_name} eq $username
 512               and not Irssi::settings_get_bool("show_own_tweets");
 513         printf $fh "id:%d %s[%s%%B\@%s%%n] %s\n",
 514           $t->{id},
 515           $prefix,
 516           ( $username ne $user ? "$username: " : "" ),
 517           $t->{user}{screen_name},
 518           $text;
 519     }
 520
 521     print scalar localtime, " - Polling for replies" if &debug;
 522     $tweets = $obj->replies( { since => HTTP::Date::time2str($last_poll) } )
 523       || [];
 524     foreach my $t ( reverse @$tweets ) {
 525         next
 526           if exists $friends{ $t->{user}{screen_name} };
 527
 528         my $text = decode_entities( $t->{text} );
 529         $text =~ s/%/%%/g;
 530         $text =~ s/(^|\W)\@([-\w]+)/$1%B\@$2%n/g;
 531         printf $fh "id:%d [%s%%B\@%s%%n] %s\n",
 532           $t->{id},
 533           ( $username ne $user ? "$username: " : "" ),
 534           $t->{user}{screen_name},
 535           $text;
 536     }
 537
 538     print scalar localtime, " - Polling for DMs" if &debug;
 539     $tweets =
 540       $obj->direct_messages( { since => HTTP::Date::time2str($last_poll) } )
 541       || [];
 542     foreach my $t ( reverse @$tweets ) {
 543         my $text = decode_entities( $t->{text} );
 544         $text =~ s/%/%%/g;
 545         $text =~ s/(^|\W)\@([-\w]+)/$1%B\@$2%n/g;
 546         printf $fh "id:%d [%s%%B\@%s%%n (%%WDM%%n)] %s\n",
 547           $t->{id},
 548           ( $username ne $user ? "$username: " : "" ),
 549           $t->{sender_screen_name},
 550           $text;
 551     }
 552     print scalar localtime, " - Done" if &debug;
 553 }
 554
 555 sub monitor_child {
 556     my $data     = shift;
 557     my $filename = $data->[0];
 558
 559     print scalar localtime, " - checking child log at $filename" if &debug;
 560     my $old_last_poll = $last_poll;
 561     if ( open FILE, $filename ) {
 562         my @lines;
 563         while (<FILE>) {
 564             chomp;
 565             last if /^__friends__/;
 566             if (s/^id:(\d+) //) {
 567                 next if exists $tweet_cache{$1};
 568                 $tweet_cache{$1} = time;
 569             }
 570             push @lines, $_ unless /^__friends__/;
 571         }
 572
 573         %friends = ();
 574         while (<FILE>) {
 575             if (/^\d+$/) {
 576                 $last_poll = $_;
 577                 last;
 578             }
 579             my ( $f, $t ) = split ' ', $_;
 580             $nicks{$f} = $friends{$f} = $t;
 581         }
 582
 583         if ( $last_poll != $old_last_poll ) {
 584             print "new last_poll = $last_poll" if &debug;
 585             foreach my $line (@lines) {
 586                 chomp $line;
 587                 $window->print( $line, MSGLEVEL_PUBLIC );
 588                 foreach ( $line =~ /\@([-\w]+)/ ) {
 589                     $nicks{$1} = time;
 590                 }
 591             }
 592
 593             close FILE;
 594             unlink $filename
 595               or warn "Failed to remove $filename: $!"
 596               unless &debug;
 597
 598       # keep 10 minutes of cached tweets, to make sure we don't show duplicates.
 599             foreach ( keys %tweet_cache ) {
 600                 next if $tweet_cache{$_} > time - 600;
 601                 delete $tweet_cache{$_};
 602             }
 603             return;
 604         }
 605     }
 606
 607     close FILE;
 608     Irssi::timeout_add_once( 5000, 'monitor_child', [$filename] );
 609 }
 610
 611 sub debug {
 612     return Irssi::settings_get_bool("twirssi_debug");
 613 }
 614
 615 sub notice {
 616     $window->print( "%R***%n @_", MSGLEVEL_PUBLIC );
 617 }
 618
 619 sub sig_complete {
 620     my ( $complist, $window, $word, $linestart, $want_space ) = @_;
 621
 622     return unless $linestart =~ /^\/(?:tweet|dm)/;
 623     my $prefix = $word =~ s/^@//;
 624     $prefix = 0 if $linestart eq '/dm' or $linestart eq '/dm_as';
 625     push @$complist, grep /^\Q$word/i,
 626       sort { $nicks{$b} <=> $nicks{$a} } keys %nicks;
 627     @$complist = map { "\@$_" } @$complist if $prefix;
 628 }
 629
 630 Irssi::settings_add_str( "twirssi", "twitter_window",     "twitter" );
 631 Irssi::settings_add_str( "twirssi", "bitlbee_server",     "bitlbee" );
 632 Irssi::settings_add_str( "twirssi", "short_url_provider", "TinyURL" );
 633 Irssi::settings_add_str( "twirssi", "twirssi_location",
 634     ".irssi/scripts/twirssi.pl" );
 635 Irssi::settings_add_str( "twirssi", "twitter_usernames", undef );
 636 Irssi::settings_add_str( "twirssi", "twitter_passwords", undef );
 637 Irssi::settings_add_bool( "twirssi", "tweet_to_away",      0 );
 638 Irssi::settings_add_bool( "twirssi", "show_reply_context", 0 );
 639 Irssi::settings_add_bool( "twirssi", "show_own_tweets",    1 );
 640 Irssi::settings_add_bool( "twirssi", "twirssi_debug",      0 );
 641 Irssi::settings_add_bool( "twirssi", "twirssi_first_run",  1 );
 642 $window = Irssi::window_find_name( Irssi::settings_get_str('twitter_window') );
 643
 644 if ($window) {
 645     Irssi::command_bind( "dm",              "cmd_direct" );
 646     Irssi::command_bind( "tweet",           "cmd_tweet" );
 647     Irssi::command_bind( "dm_as",           "cmd_direct_as" );
 648     Irssi::command_bind( "tweet_as",        "cmd_tweet_as" );
 649     Irssi::command_bind( "twitter_login",   "cmd_login" );
 650     Irssi::command_bind( "twitter_logout",  "cmd_logout" );
 651     Irssi::command_bind( "twitter_switch",  "cmd_switch" );
 652     Irssi::command_bind( "twirssi_upgrade", "cmd_upgrade" );
 653     Irssi::command_bind(
 654         "twitter_dump",
 655         sub {
 656             print "twits: ",   Dumper \%twits;
 657             print "friends: ", join ", ", sort keys %friends;
 658             print "nicks: ",   join ", ", sort keys %nicks;
 659             print "last poll: $last_poll";
 660         }
 661     );
 662     Irssi::command_bind(
 663         "twirssi_version",
 664         sub {
 665             &notice(
 666 "Twirssi v$VERSION (r$REV);  Net::Twitter v$Net::Twitter::VERSION. "
 667                   . "See details at http://tinyurl.com/twirssi" );
 668         }
 669     );
 670     Irssi::command_bind(
 671         "twitter_friend",
 672         &gen_cmd(
 673             "/twitter_friend <username>",
 674             "create_friend",
 675             sub { &notice("Following $_[0]"); $nicks{ $_[0] } = time; }
 676         )
 677     );
 678     Irssi::command_bind(
 679         "twitter_unfriend",
 680         &gen_cmd(
 681             "/twitter_unfriend <username>",
 682             "destroy_friend",
 683             sub { &notice("Stopped following $_[0]"); delete $nicks{ $_[0] }; }
 684         )
 685     );
 686     Irssi::command_bind( "twitter_updates", "get_updates" );
 687     Irssi::signal_add_last( 'complete word' => \&sig_complete );
 688
 689     &notice("  %Y<%C(%B^%C)%N                   TWIRSSI v%R$VERSION%N (r$REV)");
 690     &notice("   %C(_(\\%N        http://tinyurl.com/twirssi for full docs");
 691     &notice(
 692         "    %Y||%C `%N Log in with /twitter_login, send updates with /tweet");
 693
 694     if ( my $provider = Irssi::settings_get_str("short_url_provider") ) {
 695         eval "use WWW::Shorten::$provider;";
 696
 697         if ($@) {
 698             &notice(
 699 "Failed to load WWW::Shorten::$provider - either clear short_url_provider or install the CPAN module"
 700             );
 701         }
 702     }
 703
 704     if (    my $autouser = Irssi::settings_get_str("twitter_usernames")
 705         and my $autopass = Irssi::settings_get_str("twitter_passwords") )
 706     {
 707         &cmd_login();
 708     }
 709
 710 } else {
 711     Irssi::active_win()
 712       ->print( "Create a window named "
 713           . Irssi::settings_get_str('twitter_window')
 714           . " or change the value of twitter_window.  Then, reload twirssi." );
 715 }
 716