twirssi.pl

   1 use strict;
   2 use Irssi;
   3 use Irssi::Irc;
   4 use HTTP::Date;
   5 use HTML::Entities;
   6 use File::Temp;
   7 use LWP::Simple;
   8 use Data::Dumper;
   9 use Net::Twitter;
  10 $Data::Dumper::Indent = 1;
  11
  12 use vars qw($VERSION %IRSSI);
  13
  14 $VERSION = "2.0.6";
  15 my ($REV) = '$Rev: 488 $' =~ /(\d+)/;
  16 %IRSSI = (
  17     authors     => 'Dan Boger',
  18     contact     => 'zigdon@gmail.com',
  19     name        => 'twirssi',
  20     description => 'Send twitter updates using /tweet.  '
  21       . 'Can optionally set your bitlbee /away message to same',
  22     license => 'GNU GPL v2',
  23     url     => 'http://twirssi.com',
  24     changed => '$Date: 2009-02-24 13:57:57 -0800 (Tue, 24 Feb 2009) $',
  25 );
  26
  27 my $window;
  28 my $twit;
  29 my %twits;
  30 my $user;
  31 my $poll;
  32 my $last_poll;
  33 my %nicks;
  34 my %friends;
  35 my %tweet_cache;
  36 my %id_map;
  37 my $failwhale            = 0;
  38 my %irssi_to_mirc_colors = (
  39     '%k' => '01',
  40     '%r' => '05',
  41     '%g' => '03',
  42     '%y' => '07',
  43     '%b' => '02',
  44     '%m' => '06',
  45     '%c' => '10',
  46     '%w' => '15',
  47     '%K' => '14',
  48     '%R' => '04',
  49     '%G' => '09',
  50     '%Y' => '08',
  51     '%B' => '12',
  52     '%M' => '13',
  53     '%C' => '11',
  54     '%W' => '00',
  55 );
  56
  57 sub cmd_direct {
  58     my ( $data, $server, $win ) = @_;
  59
  60     return unless &logged_in($twit);
  61
  62     my ( $target, $text ) = split ' ', $data, 2;
  63     unless ( $target and $text ) {
  64         &notice("Usage: /dm <nick> <message>");
  65         return;
  66     }
  67
  68     &cmd_direct_as( "$user $data", $server, $win );
  69 }
  70
  71 sub cmd_direct_as {
  72     my ( $data, $server, $win ) = @_;
  73
  74     return unless &logged_in($twit);
  75
  76     my ( $username, $target, $text ) = split ' ', $data, 3;
  77     unless ( $username and $target and $text ) {
  78         &notice("Usage: /dm_as <username> <nick> <message>");
  79         return;
  80     }
  81
  82     return unless &valid_username($username);
  83
  84     eval {
  85         if ( $twits{$username}
  86             ->new_direct_message( { user => $target, text => $text } ) )
  87         {
  88             &notice("DM sent to $target");
  89             $nicks{$target} = time;
  90         } else {
  91             my $error;
  92             eval {
  93                 $error = JSON::Any->jsonToObj( $twits{$username}->get_error() );
  94                 $error = $error->{error};
  95             };
  96             die $error if $error;
  97             &notice("DM to $target failed");
  98         }
  99     };
 100
 101     if ($@) {
 102         &notice("DM caused an error: $@");
 103         return;
 104     }
 105 }
 106
 107 sub cmd_tweet {
 108     my ( $data, $server, $win ) = @_;
 109
 110     return unless &logged_in($twit);
 111
 112     $data =~ s/^\s+|\s+$//;
 113     unless ($data) {
 114         &notice("Usage: /tweet <update>");
 115         return;
 116     }
 117
 118     &cmd_tweet_as( "$user $data", $server, $win );
 119 }
 120
 121 sub cmd_tweet_as {
 122     my ( $data, $server, $win ) = @_;
 123
 124     return unless &logged_in($twit);
 125
 126     $data =~ s/^\s+|\s+$//;
 127     $data =~ s/\s\s+/ /g;
 128     my ( $username, $data ) = split ' ', $data, 2;
 129
 130     unless ( $username and $data ) {
 131         &notice("Usage: /tweet_as <username> <update>");
 132         return;
 133     }
 134
 135     return unless &valid_username($username);
 136
 137     if ( &too_long( $data, 1 )
 138         and Irssi::settings_get_str("short_url_provider") )
 139     {
 140         foreach my $url ( $data =~ /(https?:\/\/\S+[\w\/])/g ) {
 141             eval {
 142                 my $short = makeashorterlink($url);
 143                 $data =~ s/\Q$url/$short/g;
 144             };
 145         }
 146     }
 147
 148     return if &too_long($data);
 149
 150     my $success = 1;
 151     eval {
 152         unless ( $twits{$username}->update($data) )
 153         {
 154             &notice("Update failed");
 155             $success = 0;
 156         }
 157     };
 158     return unless $success;
 159
 160     if ($@) {
 161         &notice("Update caused an error: $@.  Aborted.");
 162         return;
 163     }
 164
 165     foreach ( $data =~ /@([-\w]+)/ ) {
 166         $nicks{$1} = time;
 167     }
 168
 169     my $away = &update_away($data);
 170
 171     &notice( "Update sent" . ( $away ? " (and away msg set)" : "" ) );
 172 }
 173
 174 sub cmd_reply {
 175     my ( $data, $server, $win ) = @_;
 176
 177     return unless &logged_in($twit);
 178
 179     $data =~ s/^\s+|\s+$//;
 180     unless ($data) {
 181         &notice("Usage: /reply <nick[:num]> <update>");
 182         return;
 183     }
 184
 185     $data =~ s/^\s+|\s+$//;
 186     my ( $id, $data ) = split ' ', $data, 2;
 187     unless ( $id and $data ) {
 188         &notice("Usage: /reply_as <nick[:num]> <update>");
 189         return;
 190     }
 191
 192     &cmd_reply_as( "$user $id $data", $server, $win );
 193 }
 194
 195 sub cmd_reply_as {
 196     my ( $data, $server, $win ) = @_;
 197
 198     unless ( Irssi::settings_get_bool("twirssi_track_replies") ) {
 199         &notice("twirssi_track_replies is required in order to reply to "
 200               . "specific tweets.  Either enable it, or just use /tweet "
 201               . "\@username <text>." );
 202         return;
 203     }
 204
 205     return unless &logged_in($twit);
 206
 207     $data =~ s/^\s+|\s+$//;
 208     my ( $username, $id, $data ) = split ' ', $data, 3;
 209
 210     unless ( $username and $data ) {
 211         &notice("Usage: /reply_as <username> <nick[:num]> <update>");
 212         return;
 213     }
 214
 215     return unless &valid_username($username);
 216
 217     my $nick;
 218     $id =~ s/[^\w\d\-:]+//g;
 219     ( $nick, $id ) = split /:/, $id;
 220     unless ( exists $id_map{ lc $nick } ) {
 221         &notice("Can't find a tweet from $nick to reply to!");
 222         return;
 223     }
 224
 225     $id = $id_map{__indexes}{$nick} unless $id;
 226     unless ( $id_map{ lc $nick }[$id] ) {
 227         &notice("Can't find a tweet numbered $id from $nick to reply to!");
 228         return;
 229     }
 230
 231     if ( Irssi::settings_get_bool("twirssi_replies_autonick") ) {
 232
 233         # remove any @nick at the beginning of the reply, as we'll add it anyway
 234         $data =~ s/^\s*\@?$nick\s*//;
 235         $data = "\@$nick " . $data;
 236     }
 237
 238     if ( &too_long( $data, 1 ) ) {
 239         if ( Irssi::settings_get_str("short_url_provider") ) {
 240             foreach my $url ( $data =~ /(https?:\/\/\S+[\w\/])/g ) {
 241                 eval {
 242                     my $short = makeashorterlink($url);
 243                     $data =~ s/\Q$url/$short/g;
 244                 };
 245             }
 246         }
 247     }
 248
 249     return if &too_long($data);
 250
 251     my $success = 1;
 252     eval {
 253         unless (
 254             $twits{$username}->update(
 255                 {
 256                     status                => $data,
 257                     in_reply_to_status_id => $id_map{ lc $nick }[$id]
 258                 }
 259             )
 260           )
 261         {
 262             &notice("Update failed");
 263             $success = 0;
 264         }
 265     };
 266     return unless $success;
 267
 268     if ($@) {
 269         &notice("Update caused an error: $@.  Aborted");
 270         return;
 271     }
 272
 273     foreach ( $data =~ /@([-\w]+)/ ) {
 274         $nicks{$1} = time;
 275     }
 276
 277     my $away = &update_away($data);
 278
 279     &notice( "Update sent" . ( $away ? " (and away msg set)" : "" ) );
 280 }
 281
 282 sub gen_cmd {
 283     my ( $usage_str, $api_name, $post_ref ) = @_;
 284
 285     return sub {
 286         my ( $data, $server, $win ) = @_;
 287
 288         return unless &logged_in($twit);
 289
 290         $data =~ s/^\s+|\s+$//;
 291         unless ($data) {
 292             &notice("Usage: $usage_str");
 293             return;
 294         }
 295
 296         my $success = 1;
 297         eval {
 298             unless ( $twit->$api_name($data) )
 299             {
 300                 &notice("$api_name failed");
 301                 $success = 0;
 302             }
 303         };
 304         return unless $success;
 305
 306         if ($@) {
 307             &notice("$api_name caused an error.  Aborted.");
 308             return;
 309         }
 310
 311         &$post_ref($data) if $post_ref;
 312       }
 313 }
 314
 315 sub cmd_switch {
 316     my ( $data, $server, $win ) = @_;
 317
 318     $data =~ s/^\s+|\s+$//g;
 319     if ( exists $twits{$data} ) {
 320         &notice("Switching to $data");
 321         $twit = $twits{$data};
 322         $user = $data;
 323     } else {
 324         &notice("Unknown user $data");
 325     }
 326 }
 327
 328 sub cmd_logout {
 329     my ( $data, $server, $win ) = @_;
 330
 331     $data =~ s/^\s+|\s+$//g;
 332     $data = $user unless $data;
 333     return unless &valid_username($data);
 334
 335     &notice("Logging out $data...");
 336     $twits{$data}->end_session();
 337     delete $twits{$data};
 338     undef $twit;
 339     if ( keys %twits ) {
 340         &cmd_switch( ( keys %twits )[0], $server, $win );
 341     } else {
 342         Irssi::timeout_remove($poll) if $poll;
 343         undef $poll;
 344     }
 345 }
 346
 347 sub cmd_login {
 348     my ( $data, $server, $win ) = @_;
 349     my $pass;
 350     if ($data) {
 351         ( $user, $pass ) = split ' ', $data, 2;
 352     } elsif ( my $autouser = Irssi::settings_get_str("twitter_usernames")
 353         and my $autopass = Irssi::settings_get_str("twitter_passwords") )
 354     {
 355         my @user = split /\s*,\s*/, $autouser;
 356         my @pass = split /\s*,\s*/, $autopass;
 357         if ( @user != @pass ) {
 358             &notice("Number of usernames doesn't match "
 359                   . "the number of passwords - auto-login failed" );
 360         } else {
 361             my ( $u, $p );
 362             while ( @user and @pass ) {
 363                 $u = shift @user;
 364                 $p = shift @pass;
 365                 &cmd_login("$u $p");
 366             }
 367             return;
 368         }
 369     } else {
 370         &notice("/twitter_login requires either a username and password "
 371               . "or twitter_usernames and twitter_passwords to be set." );
 372         return;
 373     }
 374
 375     %friends = %nicks = ();
 376
 377     $twit = Net::Twitter->new(
 378         username => $user,
 379         password => $pass,
 380         source   => "twirssi"
 381     );
 382
 383     unless ( $twit->verify_credentials() ) {
 384         &notice("Login as $user failed");
 385         $twit = undef;
 386         if ( keys %twits ) {
 387             &cmd_switch( ( keys %twits )[0], $server, $win );
 388         }
 389         return;
 390     }
 391
 392     if ($twit) {
 393         my $rate_limit = $twit->rate_limit_status();
 394         if ( $rate_limit and $rate_limit->{remaining_hits} < 1 ) {
 395             &notice(
 396                 "Rate limit exceeded, try again after $rate_limit->{reset_time}"
 397             );
 398             $twit = undef;
 399             return;
 400         }
 401
 402         $twits{$user} = $twit;
 403         Irssi::timeout_remove($poll) if $poll;
 404         $poll = Irssi::timeout_add( &get_poll_time * 1000, \&get_updates, "" );
 405         &notice("Logged in as $user, loading friends list...");
 406         &load_friends();
 407         &notice( "loaded friends: ", scalar keys %friends );
 408         if ( Irssi::settings_get_bool("twirssi_first_run") ) {
 409             Irssi::settings_set_bool( "twirssi_first_run", 0 );
 410             unless ( exists $friends{twirssi} ) {
 411                 &notice("Welcome to twirssi!"
 412                       . "  Perhaps you should add \@twirssi to your friends list,"
 413                       . " so you can be notified when a new version is release?"
 414                       . "  Just type /twitter_friend twirssi." );
 415             }
 416         }
 417         %nicks = %friends;
 418         $nicks{$user} = 0;
 419         return 1;
 420     } else {
 421         &notice("Login failed");
 422     }
 423 }
 424
 425 sub cmd_add_search {
 426     my ( $data, $server, $win ) = @_;
 427
 428     unless ( $twit and $twit->can('search') ) {
 429         &notice("ERROR: Your version of Net::Twitter ($Net::Twitter::VERSION) "
 430               . "doesn't support searches." );
 431         return;
 432     }
 433
 434     $data =~ s/^\s+|\s+$//;
 435     $data = lc $data;
 436
 437     unless ($data) {
 438         &notice("Usage: /twitter_subscribe <topic>");
 439         return;
 440     }
 441
 442     if ( exists $id_map{__searches}{$user}{$data} ) {
 443         &notice("Already had a subscription for '$data'");
 444         return;
 445     }
 446
 447     $id_map{__searches}{$user}{$data} = 1;
 448     &notice("Added subscription for '$data'");
 449 }
 450
 451 sub cmd_del_search {
 452     my ( $data, $server, $win ) = @_;
 453
 454     unless ( $twit and $twit->can('search') ) {
 455         &notice("ERROR: Your version of Net::Twitter ($Net::Twitter::VERSION) "
 456               . "doesn't support searches." );
 457         return;
 458     }
 459     $data =~ s/^\s+|\s+$//;
 460     $data = lc $data;
 461
 462     unless ($data) {
 463         &notice("Usage: /twitter_unsubscribe <topic>");
 464         return;
 465     }
 466
 467     unless ( exists $id_map{__searches}{$user}{$data} ) {
 468         &notice("No subscription found for '$data'");
 469         return;
 470     }
 471
 472     delete $id_map{__searches}{$user}{$data};
 473     &notice("Removed subscription for '$data'");
 474 }
 475
 476 sub cmd_list_search {
 477     my ( $data, $server, $win ) = @_;
 478
 479     my $found = 0;
 480     foreach my $suser ( sort keys %{ $id_map{__searches} } ) {
 481         my $topics;
 482         foreach my $topic ( sort keys %{ $id_map{__searches}{$suser} } ) {
 483             $topics = $topics ? "$topics, $topic" : $topic;
 484         }
 485         if ($topics) {
 486             $found = 1;
 487             &notice("Search subscriptions for \@$suser: $topics");
 488         }
 489     }
 490
 491     unless ($found) {
 492         &notice("No search subscriptions set up");
 493     }
 494 }
 495
 496 sub cmd_upgrade {
 497     my ( $data, $server, $win ) = @_;
 498
 499     my $loc = Irssi::settings_get_str("twirssi_location");
 500     unless ( -w $loc ) {
 501         &notice(
 502 "$loc isn't writable, can't upgrade.  Perhaps you need to /set twirssi_location?"
 503         );
 504         return;
 505     }
 506
 507     my $md5;
 508     unless ($data) {
 509         eval { use Digest::MD5; };
 510
 511         if ($@) {
 512             &notice(
 513 "Failed to load Digest::MD5.  Try '/twirssi_upgrade nomd5' to skip MD5 verification"
 514             );
 515             return;
 516         }
 517
 518         $md5 = get("http://twirssi.com/md5sum");
 519         chomp $md5;
 520         $md5 =~ s/ .*//;
 521         unless ($md5) {
 522             &notice("Failed to download md5sum from peeron!  Aborting.");
 523             return;
 524         }
 525
 526         unless ( open( CUR, $loc ) ) {
 527             &notice(
 528 "Failed to read $loc.  Check that /set twirssi_location is set to the correct location."
 529             );
 530             return;
 531         }
 532
 533         my $cur_md5 = Digest::MD5::md5_hex(<CUR>);
 534         close CUR;
 535
 536         if ( $cur_md5 eq $md5 ) {
 537             &notice("Current twirssi seems to be up to date.");
 538             return;
 539         }
 540     }
 541
 542     my $URL = "http://twirssi.com/twirssi.pl";
 543     &notice("Downloading twirssi from $URL");
 544     LWP::Simple::getstore( $URL, "$loc.upgrade" );
 545
 546     unless ($data) {
 547         unless ( open( NEW, "$loc.upgrade" ) ) {
 548             &notice(
 549 "Failed to read $loc.upgrade.  Check that /set twirssi_location is set to the correct location."
 550             );
 551             return;
 552         }
 553
 554         my $new_md5 = Digest::MD5::md5_hex(<NEW>);
 555         close NEW;
 556
 557         if ( $new_md5 ne $md5 ) {
 558             &notice("MD5 verification failed. expected $md5, got $new_md5");
 559             return;
 560         }
 561     }
 562
 563     rename $loc, "$loc.backup"
 564       or &notice("Failed to back up $loc: $!.  Aborting")
 565       and return;
 566     rename "$loc.upgrade", $loc
 567       or &notice("Failed to rename $loc.upgrade: $!.  Aborting")
 568       and return;
 569
 570     my ( $dir, $file ) = ( $loc =~ m{(.*)/([^/]+)$} );
 571     if ( -e "$dir/autorun/$file" ) {
 572         &notice("Updating $dir/autorun/$file");
 573         unlink "$dir/autorun/$file"
 574           or &notice("Failed to remove old $file from autorun: $!");
 575         symlink "../$file", "$dir/autorun/$file"
 576           or &notice("Failed to create symlink in autorun directory: $!");
 577     }
 578
 579     &notice("Download complete.  Reload twirssi with /script load $file");
 580 }
 581
 582 sub load_friends {
 583     my $fh   = shift;
 584     my $page = 1;
 585     my %new_friends;
 586     eval {
 587         while (1)
 588         {
 589             print $fh "type:debug Loading friends page $page...\n"
 590               if ( $fh and &debug );
 591             my $friends = $twit->friends( { page => $page } );
 592             last unless $friends;
 593             $new_friends{ $_->{screen_name} } = time foreach @$friends;
 594             $page++;
 595             last if @$friends == 0 or $page == 10;
 596         }
 597     };
 598
 599     if ($@) {
 600         print $fh "type:debug Error during friends list update.  Aborted.\n";
 601         return;
 602     }
 603
 604     my ( $added, $removed ) = ( 0, 0 );
 605     print $fh "type:debug Scanning for new friends...\n" if ( $fh and &debug );
 606     foreach ( keys %new_friends ) {
 607         next if exists $friends{$_};
 608         $friends{$_} = time;
 609         $added++;
 610     }
 611
 612     print $fh "type:debug Scanning for removed friends...\n"
 613       if ( $fh and &debug );
 614     foreach ( keys %friends ) {
 615         next if exists $new_friends{$_};
 616         delete $friends{$_};
 617         $removed++;
 618     }
 619
 620     return ( $added, $removed );
 621 }
 622
 623 sub get_updates {
 624     print scalar localtime, " - get_updates starting" if &debug;
 625
 626     $window =
 627       Irssi::window_find_name( Irssi::settings_get_str('twitter_window') );
 628     unless ($window) {
 629         Irssi::active_win()
 630           ->print( "Can't find a window named '"
 631               . Irssi::settings_get_str('twitter_window')
 632               . "'.  Create it or change the value of twitter_window" );
 633     }
 634
 635     return unless &logged_in($twit);
 636
 637     my ( $fh, $filename ) = File::Temp::tempfile();
 638     binmode( $fh, ":utf8" );
 639     my $pid = fork();
 640
 641     if ($pid) {    # parent
 642         Irssi::timeout_add_once( 5000, 'monitor_child', [ $filename, 0 ] );
 643         Irssi::pidwait_add($pid);
 644     } elsif ( defined $pid ) {    # child
 645         close STDIN;
 646         close STDOUT;
 647         close STDERR;
 648
 649         my $new_poll = time;
 650
 651         my $error = 0;
 652         $error += &do_updates( $fh, $user, $twit );
 653         foreach ( keys %twits ) {
 654             next if $_ eq $user;
 655             $error += &do_updates( $fh, $_, $twits{$_} );
 656         }
 657
 658         my ( $added, $removed ) = &load_friends($fh);
 659         if ( $added + $removed ) {
 660             print $fh "type:debug %R***%n Friends list updated: ",
 661               join( ", ",
 662                 sprintf( "%d added",   $added ),
 663                 sprintf( "%d removed", $removed ) ),
 664               "\n";
 665         }
 666         print $fh "__friends__\n";
 667         foreach ( sort keys %friends ) {
 668             print $fh "$_ $friends{$_}\n";
 669         }
 670
 671         if ($error) {
 672             print $fh "type:debug Update encountered errors.  Aborted\n";
 673             print $fh $last_poll;
 674         } else {
 675             print $fh $new_poll;
 676         }
 677         close $fh;
 678         exit;
 679     }
 680     print scalar localtime, " - get_updates ends" if &debug;
 681 }
 682
 683 sub do_updates {
 684     my ( $fh, $username, $obj ) = @_;
 685
 686     my $rate_limit = $obj->rate_limit_status();
 687     if ( $rate_limit and $rate_limit->{remaining_hits} < 1 ) {
 688         &notice("Rate limit exceeded for $username");
 689         return 1;
 690     }
 691
 692     print scalar localtime, " - Polling for updates for $username" if &debug;
 693     my $tweets;
 694     eval { $tweets = $obj->friends_timeline(); };
 695
 696     if ($@) {
 697         print $fh
 698           "type:debug Error during friends_timeline call: $@.  Aborted.\n";
 699         return 1;
 700     }
 701
 702     unless ( ref $tweets ) {
 703         if ( $obj->can("get_error") ) {
 704             my $error;
 705             eval { $error = JSON::Any->jsonToObj( $obj->get_error() ) };
 706             if ($@) { $error = $obj->get_error() }
 707             print $fh "type:debug API Error during friends_timeline call: ",
 708               "$error  Aborted.\n";
 709         } else {
 710             print $fh
 711               "type:debug API Error during friends_timeline call. Aborted.\n";
 712         }
 713         return 1;
 714     }
 715
 716     foreach my $t ( reverse @$tweets ) {
 717         my $text = decode_entities( $t->{text} );
 718         $text = &hilight($text);
 719         my $reply = "tweet";
 720         if (    Irssi::settings_get_bool("show_reply_context")
 721             and $t->{in_reply_to_screen_name} ne $username
 722             and $t->{in_reply_to_screen_name}
 723             and not exists $friends{ $t->{in_reply_to_screen_name} } )
 724         {
 725             $nicks{ $t->{in_reply_to_screen_name} } = time;
 726             my $context;
 727             eval {
 728                 $context = $obj->show_status( $t->{in_reply_to_status_id} );
 729             };
 730
 731             if ($context) {
 732                 my $ctext = decode_entities( $context->{text} );
 733                 $ctext = &hilight($ctext);
 734                 printf $fh "id:%d account:%s nick:%s type:tweet %s\n",
 735                   $context->{id}, $username,
 736                   $context->{user}{screen_name}, $ctext;
 737                 $reply = "reply";
 738             } elsif ($@) {
 739                 print $fh "type:debug request to get context failed: $@";
 740             } else {
 741                 print $fh
 742 "type:debug Failed to get context from $t->{in_reply_to_screen_name}\n"
 743                   if &debug;
 744             }
 745         }
 746         next
 747           if $t->{user}{screen_name} eq $username
 748               and not Irssi::settings_get_bool("show_own_tweets");
 749         printf $fh "id:%d account:%s nick:%s type:%s %s\n",
 750           $t->{id}, $username, $t->{user}{screen_name}, $reply, $text;
 751     }
 752
 753     print scalar localtime, " - Polling for replies" if &debug;
 754     eval {
 755         $tweets = $obj->replies( { since => HTTP::Date::time2str($last_poll) } )
 756           || [];
 757     };
 758
 759     if ($@) {
 760         print $fh "type:debug Error during replies call.  Aborted.\n";
 761         return 1;
 762     }
 763
 764     foreach my $t ( reverse @$tweets ) {
 765         next
 766           if exists $friends{ $t->{user}{screen_name} };
 767
 768         my $text = decode_entities( $t->{text} );
 769         $text = &hilight($text);
 770         printf $fh "id:%d account:%s nick:%s type:tweet %s\n",
 771           $t->{id}, $username, $t->{user}{screen_name}, $text;
 772     }
 773
 774     print scalar localtime, " - Polling for DMs" if &debug;
 775     eval {
 776         $tweets =
 777           $obj->direct_messages( { since => HTTP::Date::time2str($last_poll) } )
 778           || [];
 779     };
 780
 781     if ($@) {
 782         print $fh "type:debug Error during direct_messages call.  Aborted.\n";
 783         return 1;
 784     }
 785
 786     foreach my $t ( reverse @$tweets ) {
 787         my $text = decode_entities( $t->{text} );
 788         $text = &hilight($text);
 789         printf $fh "id:%d account:%s nick:%s type:dm %s\n",
 790           $t->{id}, $username, $t->{sender_screen_name}, $text;
 791     }
 792
 793     print scalar localtime, " - Polling for subscriptions" if &debug;
 794     if ( $obj->can('search') and $id_map{__searches}{$username} ) {
 795         my $search;
 796         foreach my $topic ( sort keys %{ $id_map{__searches}{$username} } ) {
 797             print $fh "type:debug searching for $topic since ",
 798               "$id_map{__searches}{$username}{$topic}\n";
 799             eval {
 800                 $search = $obj->search(
 801                     {
 802                         q        => $topic,
 803                         since_id => $id_map{__searches}{$username}{$topic}
 804                     }
 805                 );
 806             };
 807
 808             if ($@) {
 809                 print $fh
 810                   "type:debug Error during search($topic) call.  Aborted.\n";
 811                 return 1;
 812             }
 813
 814             unless ( $search->{max_id} ) {
 815                 print $fh
 816 "type:debug Invalid search results when searching for $topic.",
 817                   "  Aborted.\n";
 818                 return 1;
 819             }
 820
 821             $id_map{__searches}{$username}{$topic} = $search->{max_id};
 822             printf $fh "id:%d account:%s type:searchid topic:%s\n",
 823               $search->{max_id}, $username, $topic;
 824
 825             foreach my $t ( reverse @{ $search->{results} } ) {
 826                 my $text = decode_entities( $t->{text} );
 827                 $text = &hilight($text);
 828                 printf $fh "id:%d account:%s nick:%s type:search topic:%s %s\n",
 829                   $t->{id}, $username, $t->{from_user}, $topic, $text;
 830             }
 831         }
 832     }
 833
 834     print scalar localtime, " - Done" if &debug;
 835
 836     return 0;
 837 }
 838
 839 sub monitor_child {
 840     my ($data)   = @_;
 841     my $filename = $data->[0];
 842     my $attempt  = $data->[1];
 843
 844     print scalar localtime, " - checking child log at $filename ($attempt)"
 845       if &debug;
 846     my $new_last_poll;
 847
 848     # first time we run we don't want to print out *everything*, so we just
 849     # pretend
 850     my $suppress = 0;
 851     $suppress = 1 unless keys %tweet_cache;
 852
 853     if ( open FILE, $filename ) {
 854         my @lines;
 855         my %new_cache;
 856         while (<FILE>) {
 857             chomp;
 858             last if /^__friends__/;
 859             my $hilight = 0;
 860             my %meta;
 861             foreach my $key (qw/id account nick type topic/) {
 862                 if (s/^$key:(\S+)\s*//) {
 863                     $meta{$key} = $1;
 864                 }
 865             }
 866
 867             if ( not $meta{type} or $meta{type} ne 'searchid' ) {
 868                 $new_cache{ $meta{id} } = time;
 869
 870                 if ( exists $meta{id} and exists $tweet_cache{ $meta{id} } ) {
 871                     next;
 872                 }
 873             }
 874
 875             my $account = "";
 876             if ( $meta{account} ne $user ) {
 877                 $account = "$meta{account}: ";
 878             }
 879
 880             my $marker = "";
 881             if (    $meta{type} ne 'dm'
 882                 and Irssi::settings_get_bool("twirssi_track_replies")
 883                 and $meta{nick}
 884                 and $meta{id} )
 885             {
 886                 $marker = ( $id_map{__indexes}{ $meta{nick} } + 1 ) % 100;
 887                 $id_map{ lc $meta{nick} }[$marker] = $meta{id};
 888                 $id_map{__indexes}{ $meta{nick} }  = $marker;
 889                 $marker                            = ":$marker";
 890             }
 891
 892             my $hilight_color =
 893               $irssi_to_mirc_colors{ Irssi::settings_get_str("hilight_color") };
 894             if ( ( $_ =~ /\@$meta{account}\W/i )
 895                 && Irssi::settings_get_bool("twirssi_hilights") )
 896             {
 897                 $meta{nick} = "\cC$hilight_color$meta{nick}\cO";
 898                 $hilight = MSGLEVEL_HILIGHT;
 899             }
 900
 901             if ( $meta{type} =~ /tweet|reply/ ) {
 902                 push @lines,
 903                   [
 904                     ( MSGLEVEL_PUBLIC | $hilight ),
 905                     $meta{type}, $account, $meta{nick}, $marker, $_
 906                   ];
 907             } elsif ( $meta{type} eq 'search' ) {
 908                 push @lines,
 909                   [
 910                     ( MSGLEVEL_PUBLIC | $hilight ),
 911                     $meta{type}, $account, $meta{topic},
 912                     $meta{nick}, $marker,  $_
 913                   ];
 914                 if ( $meta{id} >
 915                     $id_map{__searches}{ $meta{account} }{ $meta{topic} } )
 916                 {
 917                     $id_map{__searches}{ $meta{account} }{ $meta{topic} } =
 918                       $meta{id};
 919                 }
 920             } elsif ( $meta{type} eq 'dm' ) {
 921                 push @lines,
 922                   [
 923                     ( MSGLEVEL_MSGS | $hilight ),
 924                     $meta{type}, $account, $meta{nick}, $_
 925                   ];
 926             } elsif ( $meta{type} eq 'searchid' ) {
 927                 print "Search '$meta{topic}' returned id $meta{id}" if &debug;
 928                 if ( $meta{id} >=
 929                     $id_map{__searches}{ $meta{account} }{ $meta{topic} } )
 930                 {
 931                     $id_map{__searches}{ $meta{account} }{ $meta{topic} } =
 932                       $meta{id};
 933                 } elsif (&debug) {
 934                     print "Search '$meta{topic}' returned invalid id $meta{id}";
 935                 }
 936             } elsif ( $meta{type} eq 'error' ) {
 937                 push @lines, [ MSGLEVEL_MSGS, $_ ];
 938             } elsif ( $meta{type} eq 'debug' ) {
 939                 print "$_" if &debug,;
 940             } else {
 941                 print "Unknown line type $meta{type}: $_" if &debug,;
 942             }
 943         }
 944
 945         %friends = ();
 946         while (<FILE>) {
 947             if (/^\d+$/) {
 948                 $new_last_poll = $_;
 949                 last;
 950             }
 951             my ( $f, $t ) = split ' ', $_;
 952             $nicks{$f} = $friends{$f} = $t;
 953         }
 954
 955         if ($new_last_poll) {
 956             print "new last_poll = $new_last_poll" if &debug;
 957             if ($suppress) {
 958                 print "First call, not printing updates" if &debug;
 959             } else {
 960                 foreach my $line (@lines) {
 961                     $window->printformat(
 962                         $line->[0],
 963                         "twirssi_" . $line->[1],
 964                         @$line[ 2 .. $#$line ]
 965                     );
 966                 }
 967             }
 968
 969             close FILE;
 970             unlink $filename
 971               or warn "Failed to remove $filename: $!"
 972               unless &debug;
 973
 974             # commit the pending cache lines to the actual cache, now that
 975             # we've printed our output
 976             %tweet_cache = ( %tweet_cache, %new_cache );
 977
 978             # keep enough cached tweets, to make sure we don't show duplicates.
 979             foreach ( keys %tweet_cache ) {
 980                 next if $tweet_cache{$_} >= $last_poll - 3600;
 981                 delete $tweet_cache{$_};
 982             }
 983             $last_poll = $new_last_poll;
 984
 985             # save id_map hash
 986             if ( keys %id_map
 987                 and my $file =
 988                 Irssi::settings_get_str("twirssi_replies_store") )
 989             {
 990                 if ( open JSON, ">$file" ) {
 991                     print JSON JSON::Any->objToJson( \%id_map );
 992                     close JSON;
 993                 } else {
 994                     &notice("Failed to write replies to $file: $!");
 995                 }
 996             }
 997             $failwhale = 0;
 998             return;
 999         }
1000     }
1001
1002     close FILE;
1003
1004     if ( $attempt < 24 ) {
1005         Irssi::timeout_add_once( 5000, 'monitor_child',
1006             [ $filename, $attempt + 1 ] );
1007     } else {
1008         print "Giving up on polling $filename" if &debug;
1009         unlink $filename unless &debug;
1010
1011         return unless Irssi::settings_get_bool("twirssi_notify_timeouts");
1012
1013         my $since;
1014         my @time = localtime($last_poll);
1015         if ( time - $last_poll < 24 * 60 * 60 ) {
1016             $since = sprintf( "%d:%02d", @time[ 2, 1 ] );
1017         } else {
1018             $since = scalar localtime($last_poll);
1019         }
1020
1021         if ( not $failwhale and time - $last_poll > 60 * 60 ) {
1022             foreach my $whale (
1023                 q{     v  v        v},
1024                 q{     |  |  v     |  v},
1025                 q{     | .-, |     |  |},
1026                 q{  .--./ /  |  _.---.| },
1027                 q{   '-. (__..-"       \\},
1028                 q{      \\          a    |},
1029                 q{       ',.__.   ,__.-'/},
1030                 q{         '--/_.'----'`}
1031               )
1032             {
1033                 &notice($whale);
1034             }
1035             $failwhale = 1;
1036         }
1037         &notice("Haven't been able to get updated tweets since $since");
1038     }
1039 }
1040
1041 sub debug {
1042     return Irssi::settings_get_bool("twirssi_debug");
1043 }
1044
1045 sub notice {
1046     $window->print( "%R***%n @_", MSGLEVEL_PUBLIC );
1047 }
1048
1049 sub update_away {
1050     my $data = shift;
1051
1052     if (    Irssi::settings_get_bool("tweet_to_away")
1053         and $data !~ /\@\w/
1054         and $data !~ /^[dD] / )
1055     {
1056         my $server =
1057           Irssi::server_find_tag( Irssi::settings_get_str("bitlbee_server") );
1058         if ($server) {
1059             $server->send_raw("away :$data");
1060             return 1;
1061         } else {
1062             &notice( "Can't find bitlbee server.",
1063                 "Update bitlbee_server or disable tweet_to_away" );
1064             return 0;
1065         }
1066     }
1067
1068     return 0;
1069 }
1070
1071 sub too_long {
1072     my $data    = shift;
1073     my $noalert = shift;
1074
1075     if ( length $data > 140 ) {
1076         &notice( "Tweet too long (" . length($data) . " characters) - aborted" )
1077           unless $noalert;
1078         return 1;
1079     }
1080
1081     return 0;
1082 }
1083
1084 sub valid_username {
1085     my $username = shift;
1086
1087     unless ( exists $twits{$username} ) {
1088         &notice("Unknown username $username");
1089         return 0;
1090     }
1091
1092     return 1;
1093 }
1094
1095 sub logged_in {
1096     my $obj = shift;
1097     unless ($obj) {
1098         &notice("Not logged in!  Use /twitter_login username pass!");
1099         return 0;
1100     }
1101
1102     return 1;
1103 }
1104
1105 sub sig_complete {
1106     my ( $complist, $window, $word, $linestart, $want_space ) = @_;
1107
1108     if (
1109         $linestart =~ /^\/twitter_reply(?:_as)?\s*$/
1110         or ( Irssi::settings_get_bool("twirssi_use_reply_aliases")
1111             and $linestart =~ /^\/reply(?:_as)?\s*$/ )
1112       )
1113     {    # /twitter_reply gets a nick:num
1114         $word =~ s/^@//;
1115         @$complist = map { "$_:$id_map{__indexes}{$_}" } grep /^\Q$word/i,
1116           sort keys %{ $id_map{__indexes} };
1117     }
1118
1119     # /tweet, /tweet_as, /dm, /dm_as - complete @nicks (and nicks as the first
1120     # arg to dm)
1121     if ( $linestart =~ /^\/(?:tweet|dm)/ ) {
1122         my $prefix = $word =~ s/^@//;
1123         $prefix = 0 if $linestart eq '/dm' or $linestart eq '/dm_as';
1124         push @$complist, grep /^\Q$word/i,
1125           sort { $nicks{$b} <=> $nicks{$a} } keys %nicks;
1126         @$complist = map { "\@$_" } @$complist if $prefix;
1127     }
1128 }
1129
1130 sub event_send_text {
1131     my ( $line, $server, $win ) = @_;
1132     my $awin = Irssi::active_win();
1133
1134     # if the window where we got our text was the twitter window, and the user
1135     # wants to be lazy, tweet away!
1136     if ( ( $awin->get_active_name() eq $window->{name} )
1137         and Irssi::settings_get_bool("tweet_window_input") )
1138     {
1139         &cmd_tweet( $line, $server, $win );
1140     }
1141 }
1142
1143 sub get_poll_time {
1144     my $poll = Irssi::settings_get_int("twitter_poll_interval");
1145     return $poll if $poll >= 60;
1146     return 60;
1147 }
1148
1149 sub hilight {
1150     my $text = shift;
1151
1152     if ( Irssi::settings_get_str("twirssi_nick_color") ) {
1153         my $c = Irssi::settings_get_str("twirssi_nick_color");
1154         $c = $irssi_to_mirc_colors{$c};
1155         $text =~ s/(^|\W)\@([-\w]+)/$1\cC$c\@$2\cO/g if $c;
1156     }
1157     if ( Irssi::settings_get_str("twirssi_topic_color") ) {
1158         my $c = Irssi::settings_get_str("twirssi_topic_color");
1159         $c = $irssi_to_mirc_colors{$c};
1160         $text =~ s/(^|\W)\#([-\w]+)/$1\cC$c\#$2\cO/g if $c;
1161     }
1162     $text =~ s/[\n\r]/ /g;
1163
1164     return $text;
1165 }
1166
1167 Irssi::signal_add( "send text", "event_send_text" );
1168
1169 Irssi::theme_register(
1170     [
1171         'twirssi_tweet',  '[$0%B@$1%n$2] $3',
1172         'twirssi_search', '[$0%r$1%n:%B@$2%n$3] $4',
1173         'twirssi_reply',  '[$0\--> %B@$1%n$2] $3',
1174         'twirssi_dm',     '[$0%r@$1%n (%WDM%n)] $2',
1175         'twirssi_error',  'ERROR: $0',
1176     ]
1177 );
1178
1179 Irssi::settings_add_int( "twirssi", "twitter_poll_interval", 300 );
1180 Irssi::settings_add_str( "twirssi", "twitter_window",     "twitter" );
1181 Irssi::settings_add_str( "twirssi", "bitlbee_server",     "bitlbee" );
1182 Irssi::settings_add_str( "twirssi", "short_url_provider", "TinyURL" );
1183 Irssi::settings_add_str( "twirssi", "twirssi_location",
1184     ".irssi/scripts/twirssi.pl" );
1185 Irssi::settings_add_str( "twirssi", "twitter_usernames", undef );
1186 Irssi::settings_add_str( "twirssi", "twitter_passwords", undef );
1187 Irssi::settings_add_str( "twirssi", "twirssi_replies_store",
1188     ".irssi/scripts/twirssi.json" );
1189 Irssi::settings_add_str( "twirssi", "twirssi_nick_color",  "%B" );
1190 Irssi::settings_add_str( "twirssi", "twirssi_topic_color", "%r" );
1191 Irssi::settings_add_bool( "twirssi", "tweet_to_away",             0 );
1192 Irssi::settings_add_bool( "twirssi", "show_reply_context",        0 );
1193 Irssi::settings_add_bool( "twirssi", "show_own_tweets",           1 );
1194 Irssi::settings_add_bool( "twirssi", "twirssi_debug",             0 );
1195 Irssi::settings_add_bool( "twirssi", "twirssi_first_run",         1 );
1196 Irssi::settings_add_bool( "twirssi", "twirssi_track_replies",     1 );
1197 Irssi::settings_add_bool( "twirssi", "twirssi_replies_autonick",  1 );
1198 Irssi::settings_add_bool( "twirssi", "twirssi_use_reply_aliases", 0 );
1199 Irssi::settings_add_bool( "twirssi", "twirssi_notify_timeouts",   1 );
1200 Irssi::settings_add_bool( "twirssi", "twirssi_hilights",          1 );
1201 Irssi::settings_add_bool( "twirssi", "tweet_window_input",        0 );
1202
1203 $last_poll = time - &get_poll_time;
1204 $window = Irssi::window_find_name( Irssi::settings_get_str('twitter_window') );
1205 if ( !$window ) {
1206     $window =
1207       Irssi::Windowitem::window_create(
1208         Irssi::settings_get_str('twitter_window'), 1 );
1209     $window->set_name( Irssi::settings_get_str('twitter_window') );
1210 }
1211
1212 if ($window) {
1213     Irssi::command_bind( "dm",                         "cmd_direct" );
1214     Irssi::command_bind( "dm_as",                      "cmd_direct_as" );
1215     Irssi::command_bind( "tweet",                      "cmd_tweet" );
1216     Irssi::command_bind( "tweet_as",                   "cmd_tweet_as" );
1217     Irssi::command_bind( "twitter_reply",              "cmd_reply" );
1218     Irssi::command_bind( "twitter_reply_as",           "cmd_reply_as" );
1219     Irssi::command_bind( "twitter_login",              "cmd_login" );
1220     Irssi::command_bind( "twitter_logout",             "cmd_logout" );
1221     Irssi::command_bind( "twitter_switch",             "cmd_switch" );
1222     Irssi::command_bind( "twitter_subscribe",          "cmd_add_search" );
1223     Irssi::command_bind( "twitter_unsubscribe",        "cmd_del_search" );
1224     Irssi::command_bind( "twitter_list_subscriptions", "cmd_list_search" );
1225     Irssi::command_bind( "twirssi_upgrade",            "cmd_upgrade" );
1226     if ( Irssi::settings_get_bool("twirssi_use_reply_aliases") ) {
1227         Irssi::command_bind( "reply",    "cmd_reply" );
1228         Irssi::command_bind( "reply_as", "cmd_reply_as" );
1229     }
1230     Irssi::command_bind(
1231         "twirssi_dump",
1232         sub {
1233             print "twits: ", join ", ",
1234               map { "u: $_->{username}" } values %twits;
1235             print "friends: ", join ", ", sort keys %friends;
1236             print "nicks: ",   join ", ", sort keys %nicks;
1237             print "searches: ", Dumper \%{ $id_map{__searches} };
1238             print "last poll: $last_poll";
1239             if ( open DUMP, ">/tmp/twirssi.cache.txt" ) {
1240                 print DUMP Dumper \%tweet_cache;
1241                 close DUMP;
1242                 print "cache written out to /tmp/twirssi.cache.txt";
1243             }
1244         }
1245     );
1246     Irssi::command_bind(
1247         "twirssi_version",
1248         sub {
1249             &notice("Twirssi v$VERSION (r$REV); "
1250                   . "Net::Twitter v$Net::Twitter::VERSION. "
1251                   . "JSON in use: "
1252                   . JSON::Any::handler()
1253                   . ".  See details at http://twirssi.com/" );
1254         }
1255     );
1256     Irssi::command_bind(
1257         "twitter_friend",
1258         &gen_cmd(
1259             "/twitter_friend <username>",
1260             "create_friend",
1261             sub { &notice("Following $_[0]"); $nicks{ $_[0] } = time; }
1262         )
1263     );
1264     Irssi::command_bind(
1265         "twitter_unfriend",
1266         &gen_cmd(
1267             "/twitter_unfriend <username>",
1268             "destroy_friend",
1269             sub { &notice("Stopped following $_[0]"); delete $nicks{ $_[0] }; }
1270         )
1271     );
1272     Irssi::command_bind( "twitter_updates", "get_updates" );
1273     Irssi::signal_add_last( 'complete word' => \&sig_complete );
1274
1275     &notice("  %Y<%C(%B^%C)%N                   TWIRSSI v%R$VERSION%N (r$REV)");
1276     &notice("   %C(_(\\%N           http://twirssi.com/ for full docs");
1277     &notice(
1278         "    %Y||%C `%N Log in with /twitter_login, send updates with /tweet");
1279
1280     my $file = Irssi::settings_get_str("twirssi_replies_store");
1281     if ( $file and -r $file ) {
1282         if ( open( JSON, $file ) ) {
1283             local $/;
1284             my $json = <JSON>;
1285             close JSON;
1286             eval {
1287                 my $ref = JSON::Any->jsonToObj($json);
1288                 %id_map = %$ref;
1289                 my $num = keys %{ $id_map{__indexes} };
1290                 &notice( sprintf "Loaded old replies from %d contact%s.",
1291                     $num, ( $num == 1 ? "" : "s" ) );
1292             };
1293         } else {
1294             &notice("Failed to load old replies from $file: $!");
1295         }
1296     }
1297
1298     if ( my $provider = Irssi::settings_get_str("short_url_provider") ) {
1299         eval "use WWW::Shorten::$provider;";
1300
1301         if ($@) {
1302             &notice(
1303 "Failed to load WWW::Shorten::$provider - either clear short_url_provider or install the CPAN module"
1304             );
1305         }
1306     }
1307
1308     if (    my $autouser = Irssi::settings_get_str("twitter_usernames")
1309         and my $autopass = Irssi::settings_get_str("twitter_passwords") )
1310     {
1311         &cmd_login();
1312         &get_updates;
1313     }
1314
1315 } else {
1316     Irssi::active_win()
1317       ->print( "Create a window named "
1318           . Irssi::settings_get_str('twitter_window')
1319           . " or change the value of twitter_window.  Then, reload twirssi." );
1320 }
1321
1322 # vim: set sts=4 expandtab: