twirssi.pl

   1 use strict;
   2 use Irssi;
   3 use Irssi::Irc;
   4 use HTTP::Date;
   5 use HTML::Entities;
   6 use File::Temp;
   7 use LWP::Simple;
   8 use Data::Dumper;
   9 use Net::Twitter;
  10 $Data::Dumper::Indent = 1;
  11
  12 use vars qw($VERSION %IRSSI);
  13
  14 $VERSION = "1.7.6";
  15 my ($REV) = '$Rev: 379 $' =~ /(\d+)/;
  16 %IRSSI = (
  17     authors     => 'Dan Boger',
  18     contact     => 'zigdon@gmail.com',
  19     name        => 'twirssi',
  20     description => 'Send twitter updates using /tweet.  '
  21       . 'Can optionally set your bitlbee /away message to same',
  22     license => 'GNU GPL v2',
  23     url     => 'http://tinyurl.com/twirssi',
  24     changed => '$Date: 2009-01-21 09:50:42 -0800 (Wed, 21 Jan 2009) $',
  25 );
  26
  27 my $window;
  28 my $twit;
  29 my %twits;
  30 my $user;
  31 my $poll;
  32 my %nicks;
  33 my %friends;
  34 my $last_poll = time - 300;
  35 my %tweet_cache;
  36 my %id_map;
  37
  38 sub cmd_direct {
  39     my ( $data, $server, $win ) = @_;
  40
  41     return unless &logged_in($twit);
  42
  43     my ( $target, $text ) = split ' ', $data, 2;
  44     unless ( $target and $text ) {
  45         &notice("Usage: /dm <nick> <message>");
  46         return;
  47     }
  48
  49     &cmd_direct_as( "$user $data", $server, $win );
  50 }
  51
  52 sub cmd_direct_as {
  53     my ( $data, $server, $win ) = @_;
  54
  55     return unless &logged_in($twit);
  56
  57     my ( $username, $target, $text ) = split ' ', $data, 3;
  58     unless ( $username and $target and $text ) {
  59         &notice("Usage: /dm_as <username> <nick> <message>");
  60         return;
  61     }
  62
  63     return unless &valid_username($username);
  64
  65     eval {
  66         unless ( $twits{$username}
  67             ->new_direct_message( { user => $target, text => $text } ) )
  68         {
  69             &notice("DM to $target failed");
  70             return;
  71         }
  72     };
  73
  74     if ($@) {
  75         &notice("DM caused an error.  Aborted");
  76         return;
  77     }
  78
  79     &notice("DM sent to $target");
  80     $nicks{$target} = time;
  81 }
  82
  83 sub cmd_tweet {
  84     my ( $data, $server, $win ) = @_;
  85
  86     return unless &logged_in($twit);
  87
  88     $data =~ s/^\s+|\s+$//;
  89     unless ($data) {
  90         &notice("Usage: /tweet <update>");
  91         return;
  92     }
  93
  94     &cmd_tweet_as( "$user $data", $server, $win );
  95 }
  96
  97 sub cmd_tweet_as {
  98     my ( $data, $server, $win ) = @_;
  99
 100     return unless &logged_in($twit);
 101
 102     $data =~ s/^\s+|\s+$//;
 103     my ( $username, $data ) = split ' ', $data, 2;
 104
 105     unless ( $username and $data ) {
 106         &notice("Usage: /tweet_as <username> <update>");
 107         return;
 108     }
 109
 110     return unless &valid_username($username);
 111
 112     if ( Irssi::settings_get_str("short_url_provider") ) {
 113         foreach my $url ( $data =~ /(https?:\/\/\S+[\w\/])/g ) {
 114             eval {
 115                 my $short = makeashorterlink($url);
 116                 $data =~ s/\Q$url/$short/g;
 117             };
 118         }
 119     }
 120
 121     return if &too_long($data);
 122
 123     eval {
 124         unless ( $twits{$username}->update($data) )
 125         {
 126             &notice("Update failed");
 127             return;
 128         }
 129     };
 130
 131     if ($@) {
 132         &notice("Update caused an error.  Aborted.");
 133         return;
 134     }
 135
 136     foreach ( $data =~ /@([-\w]+)/ ) {
 137         $nicks{$1} = time;
 138     }
 139
 140     my $away = &update_away($data);
 141
 142     &notice( "Update sent" . ( $away ? " (and away msg set)" : "" ) );
 143 }
 144
 145 sub cmd_reply {
 146     my ( $data, $server, $win ) = @_;
 147
 148     return unless &logged_in($twit);
 149
 150     $data =~ s/^\s+|\s+$//;
 151     unless ($data) {
 152         &notice("Usage: /reply <nick[:num]> <update>");
 153         return;
 154     }
 155
 156     $data =~ s/^\s+|\s+$//;
 157     my ( $id, $data ) = split ' ', $data, 2;
 158     unless ( $id and $data ) {
 159         &notice("Usage: /reply_as <nick[:num]> <update>");
 160         return;
 161     }
 162
 163     &cmd_reply_as( "$user $id $data", $server, $win );
 164 }
 165
 166 sub cmd_reply_as {
 167     my ( $data, $server, $win ) = @_;
 168
 169     unless ( Irssi::settings_get_bool("twirssi_track_replies") ) {
 170         &notice("twirssi_track_replies is required in order to reply to "
 171               . "specific tweets.  Either enable it, or just use /tweet "
 172               . "\@username <text>." );
 173         return;
 174     }
 175
 176     return unless &logged_in($twit);
 177
 178     $data =~ s/^\s+|\s+$//;
 179     my ( $username, $id, $data ) = split ' ', $data, 3;
 180
 181     unless ( $username and $data ) {
 182         &notice("Usage: /reply_as <username> <nick[:num]> <update>");
 183         return;
 184     }
 185
 186     return unless &valid_username($username);
 187
 188     my $nick;
 189     $id =~ s/[^\w\d\-:]+//g;
 190     ( $nick, $id ) = split /:/, $id;
 191     unless ( exists $id_map{ lc $nick } ) {
 192         &notice("Can't find a tweet from $nick to reply to!");
 193         return;
 194     }
 195
 196     $id = $id_map{__indexes}{$nick} unless $id;
 197     unless ( $id_map{ lc $nick }[$id] ) {
 198         &notice("Can't find a tweet numbered $id from $nick to reply to!");
 199         return;
 200     }
 201
 202     # remove any @nick at the beginning of the reply, as we'll add it anyway
 203     $data =~ s/^\s*\@?$nick\s*//;
 204     $data = "\@$nick " . $data;
 205
 206     if ( Irssi::settings_get_str("short_url_provider") ) {
 207         foreach my $url ( $data =~ /(https?:\/\/\S+[\w\/])/g ) {
 208             eval {
 209                 my $short = makeashorterlink($url);
 210                 $data =~ s/\Q$url/$short/g;
 211             };
 212         }
 213     }
 214
 215     return if &too_long($data);
 216
 217     eval {
 218         unless (
 219             $twits{$username}->update(
 220                 {
 221                     status                => $data,
 222                     in_reply_to_status_id => $id_map{ lc $nick }[$id]
 223                 }
 224             )
 225           )
 226         {
 227             &notice("Update failed");
 228             return;
 229         }
 230     };
 231
 232     if ($@) {
 233         &notice("Update caused an error.  Aborted");
 234         return;
 235     }
 236
 237     foreach ( $data =~ /@([-\w]+)/ ) {
 238         $nicks{$1} = time;
 239     }
 240
 241     my $away = &update_away($data);
 242
 243     &notice( "Update sent" . ( $away ? " (and away msg set)" : "" ) );
 244 }
 245
 246 sub gen_cmd {
 247     my ( $usage_str, $api_name, $post_ref ) = @_;
 248
 249     return sub {
 250         my ( $data, $server, $win ) = @_;
 251
 252         return unless &logged_in($twit);
 253
 254         $data =~ s/^\s+|\s+$//;
 255         unless ($data) {
 256             &notice("Usage: $usage_str");
 257             return;
 258         }
 259
 260         eval {
 261             unless ( $twit->$api_name($data) )
 262             {
 263                 &notice("$api_name failed");
 264                 return;
 265             }
 266         };
 267
 268         if ($@) {
 269             &notice("$api_name caused an error.  Aborted.");
 270             return;
 271         }
 272
 273         &$post_ref($data) if $post_ref;
 274       }
 275 }
 276
 277 sub cmd_switch {
 278     my ( $data, $server, $win ) = @_;
 279
 280     $data =~ s/^\s+|\s+$//g;
 281     if ( exists $twits{$data} ) {
 282         &notice("Switching to $data");
 283         $twit = $twits{$data};
 284         $user = $data;
 285     } else {
 286         &notice("Unknown user $data");
 287     }
 288 }
 289
 290 sub cmd_logout {
 291     my ( $data, $server, $win ) = @_;
 292
 293     $data =~ s/^\s+|\s+$//g;
 294     return unless &valid_username($data);
 295
 296     if ($data) {
 297         &notice("Logging out $data...");
 298         $twits{$data}->end_session();
 299         delete $twits{$data};
 300     } else {
 301         &notice("Logging out $user...");
 302         $twit->end_session();
 303         undef $twit;
 304         delete $twits{$user};
 305         if ( keys %twits ) {
 306             &cmd_switch( ( keys %twits )[0], $server, $win );
 307         } else {
 308             Irssi::timeout_remove($poll) if $poll;
 309             undef $poll;
 310         }
 311     }
 312 }
 313
 314 sub cmd_login {
 315     my ( $data, $server, $win ) = @_;
 316     my $pass;
 317     if ($data) {
 318         ( $user, $pass ) = split ' ', $data, 2;
 319     } elsif ( my $autouser = Irssi::settings_get_str("twitter_usernames")
 320         and my $autopass = Irssi::settings_get_str("twitter_passwords") )
 321     {
 322         my @user = split /\s*,\s*/, $autouser;
 323         my @pass = split /\s*,\s*/, $autopass;
 324         if ( @user != @pass ) {
 325             &notice("Number of usernames doesn't match "
 326                   . "the number of passwords - auto-login failed" );
 327         } else {
 328             my ( $u, $p );
 329             while ( @user and @pass ) {
 330                 $u = shift @user;
 331                 $p = shift @pass;
 332                 &cmd_login("$u $p");
 333             }
 334             return;
 335         }
 336     } else {
 337         &notice("/twitter_login requires either a username and password "
 338               . "or twitter_usernames and twitter_passwords to be set." );
 339         return;
 340     }
 341
 342     %friends = %nicks = ();
 343
 344     $twit = Net::Twitter->new(
 345         username => $user,
 346         password => $pass,
 347         source   => "twirssi"
 348     );
 349
 350     unless ( $twit->verify_credentials() ) {
 351         &notice("Login as $user failed");
 352         $twit = undef;
 353         if ( keys %twits ) {
 354             &cmd_switch( ( keys %twits )[0], $server, $win );
 355         }
 356         return;
 357     }
 358
 359     if ($twit) {
 360         my $rate_limit = $twit->rate_limit_status();
 361         if ( $rate_limit and $rate_limit->{remaining_hits} < 1 ) {
 362             &notice("Rate limit exceeded, try again later");
 363             $twit = undef;
 364             return;
 365         }
 366
 367         $twits{$user} = $twit;
 368         Irssi::timeout_remove($poll) if $poll;
 369         $poll = Irssi::timeout_add( 300 * 1000, \&get_updates, "" );
 370         &notice("Logged in as $user, loading friends list...");
 371         &load_friends();
 372         &notice( "loaded friends: ", scalar keys %friends );
 373         if ( Irssi::settings_get_bool("twirssi_first_run") ) {
 374             Irssi::settings_set_bool( "twirssi_first_run", 0 );
 375             unless ( exists $friends{twirssi} ) {
 376                 &notice("Welcome to twirssi!"
 377                       . "  Perhaps you should add \@twirssi to your friends list,"
 378                       . " so you can be notified when a new version is release?"
 379                       . "  Just type /twitter_friend twirssi." );
 380             }
 381         }
 382         %nicks = %friends;
 383         $nicks{$user} = 0;
 384         &get_updates;
 385     } else {
 386         &notice("Login failed");
 387     }
 388 }
 389
 390 sub cmd_upgrade {
 391     my ( $data, $server, $win ) = @_;
 392
 393     my $loc = Irssi::settings_get_str("twirssi_location");
 394     unless ( -w $loc ) {
 395         &notice(
 396 "$loc isn't writable, can't upgrade.  Perhaps you need to /set twirssi_location?"
 397         );
 398         return;
 399     }
 400
 401     if ( not -x "/usr/bin/md5sum" and not $data ) {
 402         &notice(
 403 "/usr/bin/md5sum can't be found - try '/twirssi_upgrade nomd5' to skip MD5 verification"
 404         );
 405         return;
 406     }
 407
 408     my $md5;
 409     unless ($data) {
 410         eval { use Digest::MD5; };
 411
 412         if ($@) {
 413             &notice(
 414 "Failed to load Digest::MD5.  Try '/twirssi_upgrade nomd5' to skip MD5 verification"
 415             );
 416             return;
 417         }
 418
 419         $md5 = get("http://twirssi.com/md5sum");
 420         chomp $md5;
 421         $md5 =~ s/ .*//;
 422         unless ($md5) {
 423             &notice("Failed to download md5sum from peeron!  Aborting.");
 424             return;
 425         }
 426
 427         unless ( open( CUR, $loc ) ) {
 428             &notice(
 429 "Failed to read $loc.  Check that /set twirssi_location is set to the correct location."
 430             );
 431             return;
 432         }
 433
 434         my $cur_md5 = Digest::MD5::md5_hex(<CUR>);
 435         close CUR;
 436
 437         if ( $cur_md5 eq $md5 ) {
 438             &notice("Current twirssi seems to be up to date.");
 439             return;
 440         }
 441     }
 442
 443     my $URL = "http://twirssi.com/twirssi.pl";
 444     &notice("Downloading twirssi from $URL");
 445     LWP::Simple::getstore( $URL, "$loc.upgrade" );
 446
 447     unless ($data) {
 448         unless ( open( NEW, "$loc.upgrade" ) ) {
 449             &notice(
 450 "Failed to read $loc.upgrade.  Check that /set twirssi_location is set to the correct location."
 451             );
 452             return;
 453         }
 454
 455         my $new_md5 = Digest::MD5::md5_hex(<NEW>);
 456         close NEW;
 457
 458         if ( $new_md5 ne $md5 ) {
 459             &notice("MD5 verification failed. expected $md5, got $new_md5");
 460             return;
 461         }
 462     }
 463
 464     rename $loc, "$loc.backup"
 465       or &notice("Failed to back up $loc: $!.  Aborting")
 466       and return;
 467     rename "$loc.upgrade", $loc
 468       or &notice("Failed to rename $loc.upgrade: $!.  Aborting")
 469       and return;
 470
 471     my ( $dir, $file ) = ( $loc =~ m{(.*)/([^/]+)$} );
 472     if ( -e "$dir/autorun/$file" ) {
 473         &notice("Updating $dir/autorun/$file");
 474         unlink "$dir/autorun/$file"
 475           or &notice("Failed to remove old $file from autorun: $!");
 476         symlink "../$file", "$dir/autorun/$file"
 477           or &notice("Failed to create symlink in autorun directory: $!");
 478     }
 479
 480     &notice("Download complete.  Reload twirssi with /script load $file");
 481 }
 482
 483 sub load_friends {
 484     my $fh   = shift;
 485     my $page = 1;
 486     my %new_friends;
 487     eval {
 488         while (1)
 489         {
 490             print $fh "type:debug Loading friends page $page...\n"
 491               if ( $fh and &debug );
 492             my $friends = $twit->friends( { page => $page } );
 493             last unless $friends;
 494             $new_friends{ $_->{screen_name} } = time foreach @$friends;
 495             $page++;
 496             last if @$friends == 0 or $page == 10;
 497         }
 498     };
 499
 500     if ($@) {
 501         print $fh "type:debug Error during friends list update.  Aborted.\n";
 502         return;
 503     }
 504
 505     my ( $added, $removed ) = ( 0, 0 );
 506     print $fh "type:debug Scanning for new friends...\n" if ( $fh and &debug );
 507     foreach ( keys %new_friends ) {
 508         next if exists $friends{$_};
 509         $friends{$_} = time;
 510         $added++;
 511     }
 512
 513     print $fh "type:debug Scanning for removed friends...\n"
 514       if ( $fh and &debug );
 515     foreach ( keys %friends ) {
 516         next if exists $new_friends{$_};
 517         delete $friends{$_};
 518         $removed++;
 519     }
 520
 521     return ( $added, $removed );
 522 }
 523
 524 sub get_updates {
 525     print scalar localtime, " - get_updates starting" if &debug;
 526
 527     $window =
 528       Irssi::window_find_name( Irssi::settings_get_str('twitter_window') );
 529     unless ($window) {
 530         Irssi::active_win()
 531           ->print( "Can't find a window named '"
 532               . Irssi::settings_get_str('twitter_window')
 533               . "'.  Create it or change the value of twitter_window" );
 534     }
 535
 536     return unless &logged_in($twit);
 537
 538     my ( $fh, $filename ) = File::Temp::tempfile();
 539     my $pid = fork();
 540
 541     if ($pid) {    # parent
 542         Irssi::timeout_add_once( 5000, 'monitor_child', [ $filename, 0 ] );
 543         Irssi::pidwait_add($pid);
 544     } elsif ( defined $pid ) {    # child
 545         close STDIN;
 546         close STDOUT;
 547         close STDERR;
 548
 549         my $new_poll = time;
 550
 551         my $error = 0;
 552         $error += &do_updates( $fh, $user, $twit );
 553         foreach ( keys %twits ) {
 554             next if $_ eq $user;
 555             $error += &do_updates( $fh, $_, $twits{$_} );
 556         }
 557
 558         my ( $added, $removed ) = &load_friends($fh);
 559         if ( $added + $removed ) {
 560             print $fh "type:debug %R***%n Friends list updated: ",
 561               join( ", ",
 562                 sprintf( "%d added",   $added ),
 563                 sprintf( "%d removed", $removed ) ),
 564               "\n";
 565         }
 566         print $fh "__friends__\n";
 567         foreach ( sort keys %friends ) {
 568             print $fh "$_ $friends{$_}\n";
 569         }
 570
 571         if ($error) {
 572             print $fh "type:debug Update encountered errors.  Aborted\n";
 573             print $fh $last_poll;
 574         } else {
 575             print $fh $new_poll;
 576         }
 577         close $fh;
 578         exit;
 579     }
 580     print scalar localtime, " - get_updates ends" if &debug;
 581 }
 582
 583 sub do_updates {
 584     my ( $fh, $username, $obj ) = @_;
 585
 586     print scalar localtime, " - Polling for updates for $username" if &debug;
 587     my $tweets;
 588     eval {
 589         $tweets = $obj->friends_timeline(
 590             { since => HTTP::Date::time2str($last_poll) } );
 591     };
 592
 593     if ($@) {
 594         print $fh "type:debug Error during friends_timeline call.  Aborted.\n";
 595         return 1;
 596     }
 597
 598     unless ( ref $tweets ) {
 599         if ( $obj->can("get_error") ) {
 600             my $error;
 601             eval { $error = JSON::Any->jsonToObj( $obj->get_error() ) };
 602             if ($@) { $error = $obj->get_error() }
 603             print $fh "type:debug API Error during friends_timeline call: ",
 604               "$error  Aborted.\n";
 605         } else {
 606             print $fh
 607               "type:debug API Error during friends_timeline call. Aborted.\n";
 608         }
 609         return 1;
 610     }
 611
 612     foreach my $t ( reverse @$tweets ) {
 613         my $text = decode_entities( $t->{text} );
 614         $text =~ s/%/%%/g;
 615         $text =~ s/(^|\W)\@([-\w]+)/$1%B\@$2%n/g;
 616         $text =~ s/[\n\r]/ /g;
 617         my $reply = "tweet";
 618         if (    Irssi::settings_get_bool("show_reply_context")
 619             and $t->{in_reply_to_screen_name} ne $username
 620             and $t->{in_reply_to_screen_name}
 621             and not exists $friends{ $t->{in_reply_to_screen_name} } )
 622         {
 623             $nicks{ $t->{in_reply_to_screen_name} } = time;
 624             my $context;
 625             eval {
 626                 $context = $obj->show_status( $t->{in_reply_to_status_id} );
 627             };
 628
 629             if ($context) {
 630                 my $ctext = decode_entities( $context->{text} );
 631                 $ctext =~ s/%/%%/g;
 632                 $ctext =~ s/(^|\W)\@([-\w]+)/$1%B\@$2%n/g;
 633                 $ctext =~ s/[\n\r]/ /g;
 634                 printf $fh "id:%d account:%s nick:%s type:tweet %s\n",
 635                   $context->{id}, $username,
 636                   $context->{user}{screen_name}, $ctext;
 637                 $reply = "reply";
 638             } elsif ($@) {
 639                 print $fh "type:debug request to get context failed: $@";
 640             } else {
 641                 print $fh
 642 "type:debug Failed to get context from $t->{in_reply_to_screen_name}"
 643                   if &debug;
 644             }
 645         }
 646         next
 647           if $t->{user}{screen_name} eq $username
 648               and not Irssi::settings_get_bool("show_own_tweets");
 649         printf $fh "id:%d account:%s nick:%s type:%s %s\n",
 650           $t->{id}, $username, $t->{user}{screen_name}, $reply, $text;
 651     }
 652
 653     print scalar localtime, " - Polling for replies" if &debug;
 654     eval {
 655         $tweets = $obj->replies( { since => HTTP::Date::time2str($last_poll) } )
 656           || [];
 657     };
 658
 659     if ($@) {
 660         print $fh "type:debug Error during replies call.  Aborted.\n";
 661         return 1;
 662     }
 663
 664     foreach my $t ( reverse @$tweets ) {
 665         next
 666           if exists $friends{ $t->{user}{screen_name} };
 667
 668         my $text = decode_entities( $t->{text} );
 669         $text =~ s/%/%%/g;
 670         $text =~ s/(^|\W)\@([-\w]+)/$1%B\@$2%n/g;
 671         $text =~ s/[\n\r]/ /g;
 672         printf $fh "id:%d account:%s nick:%s type:tweet %s\n",
 673           $t->{id}, $username, $t->{user}{screen_name}, $text;
 674     }
 675
 676     print scalar localtime, " - Polling for DMs" if &debug;
 677     eval {
 678         $tweets =
 679           $obj->direct_messages( { since => HTTP::Date::time2str($last_poll) } )
 680           || [];
 681     };
 682
 683     if ($@) {
 684         print $fh "type:debug Error during direct_messages call.  Aborted.\n";
 685         return 1;
 686     }
 687
 688     foreach my $t ( reverse @$tweets ) {
 689         my $text = decode_entities( $t->{text} );
 690         $text =~ s/%/%%/g;
 691         $text =~ s/(^|\W)\@([-\w]+)/$1%B\@$2%n/g;
 692         $text =~ s/[\n\r]/ /g;
 693         printf $fh "id:%d account:%s nick:%s type:dm %s\n",
 694           $t->{id}, $username, $t->{sender_screen_name}, $text;
 695     }
 696     print scalar localtime, " - Done" if &debug;
 697
 698     return 0;
 699 }
 700
 701 sub monitor_child {
 702     my ($data)   = @_;
 703     my $filename = $data->[0];
 704     my $attempt  = $data->[1];
 705
 706     print scalar localtime, " - checking child log at $filename ($attempt)"
 707       if &debug;
 708     my $new_last_poll;
 709     if ( open FILE, $filename ) {
 710         my @lines;
 711         while (<FILE>) {
 712             chomp;
 713             last if /^__friends__/;
 714             my %meta;
 715             foreach my $key (qw/id account nick type/) {
 716                 if (s/^$key:(\S+)\s*//) {
 717                     $meta{$key} = $1;
 718                 }
 719             }
 720
 721             next if exists $meta{id} and exists $tweet_cache{ $meta{id} };
 722             $tweet_cache{ $meta{id} } = time;
 723             my $account = "";
 724             if ( $meta{account} ne $user ) {
 725                 $account = "$meta{account}: ";
 726             }
 727
 728             my $marker = "";
 729             if (    $meta{type} ne 'dm'
 730                 and Irssi::settings_get_bool("twirssi_track_replies")
 731                 and $meta{nick}
 732                 and $meta{id} )
 733             {
 734                 $marker = ( $id_map{__indexes}{ $meta{nick} } + 1 ) % 100;
 735                 $id_map{ lc $meta{nick} }[$marker] = $meta{id};
 736                 $id_map{__indexes}{ $meta{nick} }  = $marker;
 737                 $marker                            = ":$marker";
 738             }
 739
 740             if ( $meta{type} eq 'tweet' ) {
 741                 push @lines, "[$account%B\@$meta{nick}%n$marker] $_\n",;
 742             } elsif ( $meta{type} eq 'reply' ) {
 743                 push @lines, "[$account\\--> %B\@$meta{nick}%n$marker] $_\n",;
 744             } elsif ( $meta{type} eq 'dm' ) {
 745                 push @lines, "[$account%B\@$meta{nick}%n (%WDM%n)] $_\n",;
 746             } elsif ( $meta{type} eq 'error' ) {
 747                 push @lines, "ERROR: $_\n";
 748             } elsif ( $meta{type} eq 'debug' ) {
 749                 print "$_" if &debug,;
 750             } else {
 751                 print "Unknown line type $meta{type}: $_" if &debug,;
 752             }
 753         }
 754
 755         %friends = ();
 756         while (<FILE>) {
 757             if (/^\d+$/) {
 758                 $new_last_poll = $_;
 759                 last;
 760             }
 761             my ( $f, $t ) = split ' ', $_;
 762             $nicks{$f} = $friends{$f} = $t;
 763         }
 764
 765         if ($new_last_poll) {
 766             print "new last_poll = $new_last_poll" if &debug;
 767             foreach my $line (@lines) {
 768                 chomp $line;
 769                 $window->print( $line, MSGLEVEL_PUBLIC );
 770                 foreach ( $line =~ /\@([-\w]+)/ ) {
 771                     $nicks{$1} = time;
 772                 }
 773             }
 774
 775             close FILE;
 776             unlink $filename
 777               or warn "Failed to remove $filename: $!"
 778               unless &debug;
 779
 780             # keep enough cached tweets, to make sure we don't show duplicates.
 781             foreach ( keys %tweet_cache ) {
 782                 next if $tweet_cache{$_} >= $last_poll;
 783                 delete $tweet_cache{$_};
 784             }
 785             $last_poll = $new_last_poll;
 786
 787             # save id_map hash
 788             if ( keys %id_map
 789                 and my $file =
 790                 Irssi::settings_get_str("twirssi_replies_store") )
 791             {
 792                 if ( open JSON, ">$file" ) {
 793                     print JSON JSON::Any->objToJson( \%id_map );
 794                     close JSON;
 795                 } else {
 796                     &notice("Failed to write replies to $file: $!");
 797                 }
 798             }
 799             return;
 800         }
 801     }
 802
 803     close FILE;
 804
 805     if ( $attempt < 12 ) {
 806         Irssi::timeout_add_once( 5000, 'monitor_child',
 807             [ $filename, $attempt + 1 ] );
 808     } else {
 809         &notice("Giving up on polling $filename");
 810         unlink $filename unless &debug;
 811     }
 812 }
 813
 814 sub debug {
 815     return Irssi::settings_get_bool("twirssi_debug");
 816 }
 817
 818 sub notice {
 819     $window->print( "%R***%n @_", MSGLEVEL_PUBLIC );
 820 }
 821
 822 sub update_away {
 823     my $data = shift;
 824
 825     if (    Irssi::settings_get_bool("tweet_to_away")
 826         and $data !~ /\@\w/
 827         and $data !~ /^[dD] / )
 828     {
 829         my $server =
 830           Irssi::server_find_tag( Irssi::settings_get_str("bitlbee_server") );
 831         if ($server) {
 832             $server->send_raw("away :$data");
 833             return 1;
 834         } else {
 835             &notice( "Can't find bitlbee server.",
 836                 "Update bitlbee_server or disable tweet_to_away" );
 837             return 0;
 838         }
 839     }
 840
 841     return 0;
 842 }
 843
 844 sub too_long {
 845     my $data = shift;
 846
 847     if ( length $data > 140 ) {
 848         &notice(
 849             "Tweet too long (" . length($data) . " characters) - aborted" );
 850         return 1;
 851     }
 852
 853     return 0;
 854 }
 855
 856 sub valid_username {
 857     my $username = shift;
 858
 859     unless ( exists $twits{$username} ) {
 860         &notice("Unknown username $username");
 861         return 0;
 862     }
 863
 864     return 1;
 865 }
 866
 867 sub logged_in {
 868     my $obj = shift;
 869     unless ($obj) {
 870         &notice("Not logged in!  Use /twitter_login username pass!");
 871         return 0;
 872     }
 873
 874     return 1;
 875 }
 876
 877 sub sig_complete {
 878     my ( $complist, $window, $word, $linestart, $want_space ) = @_;
 879
 880     if (
 881         $linestart =~ /^\/twitter_reply(?:_as)?\s*$/
 882         or ( Irssi::settings_get_bool("twirssi_use_reply_aliases")
 883             and $linestart =~ /^\/reply(?:_as)?\s*$/ )
 884       )
 885     {    # /twitter_reply gets a nick:num
 886         $word =~ s/^@//;
 887         @$complist = map { "$_:$id_map{__indexes}{$_}" } grep /^\Q$word/i,
 888           sort keys %{ $id_map{__indexes} };
 889     }
 890
 891     # /tweet, /tweet_as, /dm, /dm_as - complete @nicks (and nicks as the first
 892     # arg to dm)
 893     if ( $linestart =~ /^\/(?:tweet|dm)/ ) {
 894         my $prefix = $word =~ s/^@//;
 895         $prefix = 0 if $linestart eq '/dm' or $linestart eq '/dm_as';
 896         push @$complist, grep /^\Q$word/i,
 897           sort { $nicks{$b} <=> $nicks{$a} } keys %nicks;
 898         @$complist = map { "\@$_" } @$complist if $prefix;
 899     }
 900 }
 901
 902 sub event_send_text {
 903     my ( $line, $server, $win ) = @_;
 904     my $awin = Irssi::active_win();
 905
 906     # if the window where we got our text was the twitter window, and the user
 907     # wants to be lazy, tweet away!
 908     if ( ( $awin->get_active_name() eq $window->{name} )
 909         and Irssi::settings_get_bool("tweet_window_input") )
 910     {
 911         &cmd_tweet( $line, $server, $win );
 912     }
 913 }
 914
 915 Irssi::signal_add( "send text", "event_send_text" );
 916
 917 Irssi::settings_add_str( "twirssi", "twitter_window",     "twitter" );
 918 Irssi::settings_add_str( "twirssi", "bitlbee_server",     "bitlbee" );
 919 Irssi::settings_add_str( "twirssi", "short_url_provider", "TinyURL" );
 920 Irssi::settings_add_str( "twirssi", "twirssi_location",
 921     ".irssi/scripts/twirssi.pl" );
 922 Irssi::settings_add_str( "twirssi", "twitter_usernames", undef );
 923 Irssi::settings_add_str( "twirssi", "twitter_passwords", undef );
 924 Irssi::settings_add_str( "twirssi", "twirssi_replies_store",
 925     ".irssi/scripts/twirssi.json" );
 926 Irssi::settings_add_bool( "twirssi", "tweet_to_away",             0 );
 927 Irssi::settings_add_bool( "twirssi", "show_reply_context",        0 );
 928 Irssi::settings_add_bool( "twirssi", "show_own_tweets",           1 );
 929 Irssi::settings_add_bool( "twirssi", "twirssi_debug",             0 );
 930 Irssi::settings_add_bool( "twirssi", "twirssi_first_run",         1 );
 931 Irssi::settings_add_bool( "twirssi", "twirssi_track_replies",     1 );
 932 Irssi::settings_add_bool( "twirssi", "twirssi_use_reply_aliases", 0 );
 933 Irssi::settings_add_bool( "twirssi", "tweet_window_input",        0 );
 934 $window = Irssi::window_find_name( Irssi::settings_get_str('twitter_window') );
 935
 936 if ($window) {
 937     Irssi::command_bind( "dm",               "cmd_direct" );
 938     Irssi::command_bind( "dm_as",            "cmd_direct_as" );
 939     Irssi::command_bind( "tweet",            "cmd_tweet" );
 940     Irssi::command_bind( "tweet_as",         "cmd_tweet_as" );
 941     Irssi::command_bind( "twitter_reply",    "cmd_reply" );
 942     Irssi::command_bind( "twitter_reply_as", "cmd_reply_as" );
 943     Irssi::command_bind( "twitter_login",    "cmd_login" );
 944     Irssi::command_bind( "twitter_logout",   "cmd_logout" );
 945     Irssi::command_bind( "twitter_switch",   "cmd_switch" );
 946     Irssi::command_bind( "twirssi_upgrade",  "cmd_upgrade" );
 947     if ( Irssi::settings_get_bool("twirssi_use_reply_aliases") ) {
 948         Irssi::command_bind( "reply",    "cmd_reply" );
 949         Irssi::command_bind( "reply_as", "cmd_reply_as" );
 950     }
 951     Irssi::command_bind(
 952         "twirssi_dump",
 953         sub {
 954             print "twits: ", join ", ",
 955               map { "u: $_->{username}" } values %twits;
 956             print "friends: ", join ", ", sort keys %friends;
 957             print "nicks: ",   join ", ", sort keys %nicks;
 958             print "id_map: ", Dumper \%{ $id_map{__indexes} };
 959             print "last poll: $last_poll";
 960         }
 961     );
 962     Irssi::command_bind(
 963         "twirssi_version",
 964         sub {
 965             &notice("Twirssi v$VERSION (r$REV); "
 966                   . "Net::Twitter v$Net::Twitter::VERSION. "
 967                   . "JSON in use: "
 968                   . JSON::Any::handler()
 969                   . ".  See details at http://twirssi.com/" );
 970         }
 971     );
 972     Irssi::command_bind(
 973         "twitter_friend",
 974         &gen_cmd(
 975             "/twitter_friend <username>",
 976             "create_friend",
 977             sub { &notice("Following $_[0]"); $nicks{ $_[0] } = time; }
 978         )
 979     );
 980     Irssi::command_bind(
 981         "twitter_unfriend",
 982         &gen_cmd(
 983             "/twitter_unfriend <username>",
 984             "destroy_friend",
 985             sub { &notice("Stopped following $_[0]"); delete $nicks{ $_[0] }; }
 986         )
 987     );
 988     Irssi::command_bind( "twitter_updates", "get_updates" );
 989     Irssi::signal_add_last( 'complete word' => \&sig_complete );
 990
 991     &notice("  %Y<%C(%B^%C)%N                   TWIRSSI v%R$VERSION%N (r$REV)");
 992     &notice("   %C(_(\\%N           http://twirssi.com/ for full docs");
 993     &notice(
 994         "    %Y||%C `%N Log in with /twitter_login, send updates with /tweet");
 995
 996     my $file = Irssi::settings_get_str("twirssi_replies_store");
 997     if ( $file and -r $file ) {
 998         if ( open( JSON, $file ) ) {
 999             local $/;
1000             my $json = <JSON>;
1001             close JSON;
1002             eval {
1003                 my $ref = JSON::Any->jsonToObj($json);
1004                 %id_map = %$ref;
1005                 my $num = keys %{ $id_map{__indexes} };
1006                 &notice( sprintf "Loaded old replies from %d contact%s.",
1007                     $num, ( $num == 1 ? "" : "s" ) );
1008             };
1009         } else {
1010             &notice("Failed to load old replies from $file: $!");
1011         }
1012     }
1013
1014     if ( my $provider = Irssi::settings_get_str("short_url_provider") ) {
1015         eval "use WWW::Shorten::$provider;";
1016
1017         if ($@) {
1018             &notice(
1019 "Failed to load WWW::Shorten::$provider - either clear short_url_provider or install the CPAN module"
1020             );
1021         }
1022     }
1023
1024     if (    my $autouser = Irssi::settings_get_str("twitter_usernames")
1025         and my $autopass = Irssi::settings_get_str("twitter_passwords") )
1026     {
1027         &cmd_login();
1028     }
1029
1030 } else {
1031     Irssi::active_win()
1032       ->print( "Create a window named "
1033           . Irssi::settings_get_str('twitter_window')
1034           . " or change the value of twitter_window.  Then, reload twirssi." );
1035 }
1036